~> 弃用通知 Equinix Metal 将于2026年6月30日停止服务。所有 Metal 资源将在该提供程序的 5.0.0 版本中移除。如需继续使用，请使用该提供程序的 4.x 版本直至服务终止。更多信息，请访问 https://docs.equinix.com/metal/。

equinix_metal_vrf（资源）

使用此资源管理 VRF。

有关产品详情和 API 参考资料，请参阅虚拟路由和转发文档。

用法示例

在所需的城市中创建 VRF，并指定 VRF 路由和转发的任何 IP 地址范围。

resource "equinix_metal_project" "example" {
    name = "example"
}

resource "equinix_metal_vrf" "example" {
    description = "VRF with ASN 65000 and a pool of address space that includes 192.168.100.0/25"
    name        = "example-vrf"
    metro       = "da"
    local_asn   = "65000"
    ip_ranges   = ["192.168.100.0/25", "192.168.200.0/25"]
    project_id  = equinix_metal_project.example.id
}

创建 IP 地址预留并将其分配给 Metal Gateway 资源。Gateway 将被分配该地址块中的第一个地址。

resource "equinix_metal_reserved_ip_block" "example" {
    description = "Reserved IP block (192.168.100.0/29) taken from on of the ranges in the VRF's pool of address space."
    project_id  = equinix_metal_project.example.id
    metro       = equinix_metal_vrf.example.metro
    type        = "vrf"
    vrf_id      = equinix_metal_vrf.example.id
    cidr        = 29
    network     = "192.168.100.0"
}

resource "equinix_metal_vlan" "example" {
    description = "A VLAN for Layer2 and Hybrid Metal devices"
    metro       = equinix_metal_vrf.example.metro
    project_id  = equinix_metal_project.example.id
}

resource "equinix_metal_gateway" "example" {
    project_id        = equinix_metal_project.example.id
    vlan_id           = equinix_metal_vlan.example.id
    ip_reservation_id = equinix_metal_reserved_ip_block.example.id
}

将来自专用金属连接的虚拟电路连接到金属网关。

data "equinix_metal_connection" "example" {
    connection_id = var.metal_dedicated_connection_id
}

resource "equinix_metal_virtual_circuit" "example" {
    name          = "example-vc"
    description   = "Virtual Circuit"
    connection_id = data.equinix_metal_connection.example.id
    project_id    = equinix_metal_project.example.id
    port_id       = data.equinix_metal_connection.example.ports[0].id
    nni_vlan      = 1024
    vrf_id        = equinix_metal_vrf.example.id
    peer_asn      = 65530
    subnet        = "192.168.100.16/31"
    metal_ip      = "192.168.100.16"
    customer_ip   = "192.168.100.17"
}

模式

需要

• metro（字符串）VRF 将部署到的 Metro ID 或代码
• name（字符串）用户提供的 VRF 名称，该项目中该名称是唯一的。
• project_id（字符串）VRF 将部署到的项目 ID

可选

• description（字符串）VRF 的描述
• ip_ranges（字符串集合）所有可供 BGP 对等体使用的 IPv4 和 IPv6 地址范围。IPv4 地址必须为 /8 或更小，最小为 /29。IPv6 地址必须为 /56 或更小，最小为 /64。地址范围不得与 VRF 内的其他地址范围重叠。
• local_asn（数字）VRF 上设置的 4 字节 ASN。

只读

• id（字符串）此资源的 ID。

进口

可以使用现有的 VRF ID 导入此资源：

terraform import equinix_metal_vrf {existing_id}