跳至内容

~> 弃用通知 Equinix Metal 将于2026年6月30日停止服务。所有 Metal 资源将在该提供程序的 5.0.0 版本中移除。如需继续使用，请使用该提供程序的 4.x 版本直至服务终止。更多信息，请访问 https://docs.equinix.com/metal/。

equinix_metal_port_vlan_attachment（资源）

提供将设备端口连接到 VLAN 的资源。

设备和 VLAN 必须位于同一城域网内。

如果您需要此资源在移除时将端口添加回 bond，请设置 force_bond = true。

要了解有关 Equinix Metal 中二层网络的更多信息，请参阅

用法示例​

混合网络类型​

resource "equinix_metal_vlan" "test" {
  description = "VLAN in New York"
  metro       = "ny"
  project_id  = local.project_id
}

resource "equinix_metal_device" "test" {
  hostname         = "test"
  plan             = "c3.small.x86"
  metro            = "ny"
  operating_system = "ubuntu_24_04"
  billing_cycle    = "hourly"
  project_id       = local.project_id
}

resource "equinix_metal_device_network_type" "test" {
  device_id = equinix_metal_device.test.id
  type      = "hybrid"
}

resource "equinix_metal_port_vlan_attachment" "test" {
  device_id = equinix_metal_device_network_type.test.id
  port_name = "eth1"
  vlan_vnid = equinix_metal_vlan.test.vxlan
}

二层网络​

resource "equinix_metal_device" "test" {
  hostname         = "test"
  plan             = "c3.small.x86"
  metro            = "ny"
  operating_system = "ubuntu_24_04"
  billing_cycle    = "hourly"
  project_id       = local.project_id
}

resource "equinix_metal_device_network_type" "test" {
  device_id = equinix_metal_device.test.id
  type      = "layer2-individual"
}

resource "equinix_metal_vlan" "test1" {
  description = "VLAN in New York"
  metro       = "ny"
  project_id  = local.project_id
}

resource "equinix_metal_vlan" "test2" {
  description = "VLAN in New Jersey"
  metro       = "ny"
  project_id  = local.project_id
}

resource "equinix_metal_port_vlan_attachment" "test1" {
  device_id = equinix_metal_device_network_type.test.id
  vlan_vnid = equinix_metal_vlan.test1.vxlan
  port_name = "eth1"
}

resource "equinix_metal_port_vlan_attachment" "test2" {
  device_id  = equinix_metal_device_network_type.test.id
  vlan_vnid  = equinix_metal_vlan.test2.vxlan
  port_name  = "eth1"
  native     = true
  depends_on = ["equinix_metal_port_vlan_attachment.test1"]
}

论证参考​

以下论点得到支持：

  • device_id - （必填）要分配给 VLAN 的设备的 ID。
  • port_name - （必填）要分配给 VLAN 的网络端口名称。
  • vlan_vnid - （必填）VXLAN 网络标识符。
  • force_bond - （可选）移除此资源时，将端口重新添加到绑定中。默认值为 false。
  • native - （可选）将此 VLAN 标记为端口上的原生 VLAN。仅当此分配为端口分配了第二个或多个 VLAN 时，才能使用此选项。为确保此连接不是端口上的第一个连接，您可以使用 depends_on 指向另一个 equinix_metal_port_vlan_attachment，就像上面的 layer2-individual 示例中那样。

属性参考​

除了上述所有参数外，还会导出以下属性：

  • id - 分配中使用的设备端口的 UUID。
  • vlan_id - VLAN API 资源的 UUID。
  • port_id - 设备端口的 UUID。
此页面有帮助吗？