Skip to main content

equinix_fabric_connection (Resource)

Fabric V4 API compatible resource allows creation and management of Equinix Fabric connection

Additional documentation:

Supporting Modules​

The direct usage of the resources is given in the next section "Example Usage". We also have supporting Terraform Modules that can be used to assist you with common Fabric Connection use cases.

You can find those modules along with their usage examples on the Terraform Registry: (Fabric Terraform Modules)

Example Usage​

Port to Port EVPL_VC Connection:

resource "equinix_fabric_connection" "port2port" {
  name = "ConnectionName"
  type = "EVPL_VC"
  notifications {
    type = "ALL"
    emails = ["example@equinix.com","test1@equinix.com"]
  }
  bandwidth = 50
  order {
    purchase_order_number= "1-323292"
  }
  a_side {
    access_point {
      type = "COLO"
      port {
        uuid = "<aside_port_uuid>"
      }
      link_protocol {
        type = "QINQ"
        vlan_s_tag = "1976"
        
      }
    }
  }
  z_side {
    access_point {
      type = "COLO"
      port {
        uuid = "<zside_port_uuid>"
      }
      link_protocol {
        type = "QINQ"
        vlan_s_tag = "3711"
      }
      location {
        metro_code= "SV"
      }
    }
  }
}

Port to AWS EVPL_VC Connection:

resource "equinix_fabric_connection" "port2aws" {
  name = "ConnectionName"
  type = "EVPL_VC"
  notifications {
    type = "ALL"
    emails = ["example@equinix.com","test1@equinix.com"]
  }
  bandwidth = 50
  redundancy { priority= "PRIMARY" }
  order {
    purchase_order_number= "1-323929"
  }
  a_side {
    access_point {
      type= "COLO"
      port {
        uuid = "<aside_port_uuid>"
      }
      link_protocol {
        type = "QINQ"
        vlan_s_tag = "2019"
        vlan_c_tag = "2112"
      }
    }
  }
  z_side {
    access_point {
      type = "SP"
      authentication_key = "<aws_account_id>"
      seller_region = "us-west-1"
      profile {
        type = "L2_PROFILE"
        uuid = "<service_profile_uuid>"
      }
      location {
        metro_code = "SV"
      }
    }
  }
  
  additional_info = [
    { key = "accessKey", value = "<aws_access_key>" },
    { key = "secretKey", value = "<aws_secret_key>" }
  ]
}

Port to Port EPL Connection:

resource "equinix_fabric_connection" "epl" {
  name = "ConnectionName"
  type = "EPL_VC"
  notifications {
    type   = "ALL"
    emails = ["example@equinix.com", "test1@equinix.com"]
  }
  bandwidth = 50
  order {
    purchase_order_number = "1-323292"
  }
  a_side {
    access_point {
      type = "COLO"
      port {
        uuid = "<aside_port_uuid>"
      }
    }
  }
  z_side {
    access_point {
      type = "COLO"
      port {
        uuid = "<zside_port_uuid>"
      }
      location {
        metro_code = "SV"
      }
    }
  }
}

Port to Port ACCESS_EPL_VC Connection:

resource "equinix_fabric_connection" "access_epl_vc" {
  name = "ConnectionName"
  type = "ACCESS_EPL_VC"
  notifications {
    type   = "ALL"
    emails = ["example@equinix.com", "test1@equinix.com"]
  }
  bandwidth = 50
  order {
    purchase_order_number = "1-323292"
  }
  a_side {
    access_point {
      type = "COLO"
      port {
        uuid = "<aside_port_uuid>"
      }
      link_protocol {
        type       = "QINQ"
        vlan_s_tag = "1976"
      }
    }
  }
  z_side {
    access_point {
      type = "COLO"
      port {
        uuid = "<zside_port_uuid>"
      }
      location {
        metro_code = "SV"
      }
    }
  }
}

Virtual Device to Port Connection:

resource "equinix_fabric_connection" "vd2port" {
  name = "ConnectionName"
  type = "EVPL_VC"
  notifications {
    type   = "ALL"
    emails = ["example@equinix.com", "test1@equinix.com"]
  }
  bandwidth = 50
  order {
    purchase_order_number = "1-323292"
  }
  a_side {
    access_point {
      type = "VD"
      virtual_device {
        type = "EDGE"
        uuid = "<device_uuid>"
      }
      interface {
        type = "NETWORK"
        id = 7
      }
    }
  }
  z_side {
    access_point {
      type = "COLO"
      port {
        uuid = "<zside_port_uuid>"
      }
      link_protocol {
        type       = "DOT1Q"
        vlan_s_tag = "3711"
      }
      location {
        metro_code = "SV"
      }
    }
  }
}

Virtual Device to Service Token Connection:

resource "equinix_fabric_connection" "vd2token" {
  name = "ConnectionName"
  type = "EVPL_VC"
  notifications {
    type   = "ALL"
    emails = ["example@equinix.com", "test1@equinix.com"]
  }
  bandwidth = 50
  order {
    purchase_order_number = "1-323292"
  }
  a_side {
    access_point {
      type = "VD"
      virtual_device {
        type = "EDGE"
        uuid = "<device_uuid>"
      }
      interface {
        type = "NETWORK"
        id = 7
      }
    }
  }
  z_side {
    service_token {
      uuid = "<service_token_uuid>"
    }
  }
}

Service Token to AWS Connection:

resource "equinix_fabric_connection" "token2aws" {
  name = "ConnectionName"
  type = "EVPL_VC"
  notifications {
    type   = "ALL"
    emails = ["example@equinix.com", "test1@equinix.com"]
  }
  bandwidth = 50
  order {
    purchase_order_number = "1-323292"
  }
  a_side {
    service_token {
      uuid = "<service_token_uuid>"
    }
  }
  z_side {
    access_point {
      type = "SP"
      authentication_key = "<aws_account_id>"
      seller_region = "us-west-1"
      profile {
        type = "L2_PROFILE"
        uuid = "<service_profile_uuid>"
      }
      location {
        metro_code = "SV"
      }
    }
  }
}

Cloud Router to Port Connection:

resource "equinix_fabric_connection" "fcr2port"{
  name = "ConnectionName"
  type = "IP_VC"
  notifications{
    type = "ALL"
    emails = ["example@equinix.com","test1@equinix.com"]
  }
  bandwidth = 50
  order {
    purchase_order_number = "1-323292"
  }
  a_side {
    access_point {
      type = "CLOUD_ROUTER"
      router {
        uuid = "<cloud_router_uuid>"
      }
    }
  }
  z_side {
    access_point {
      type = "COLO"
      port {
        uuid = "<port_uuid>"
      }
      link_protocol {
        type = "DOT1Q"
        vlan_tag = "2711"
      }
      location {
        metro_code = "SV"
      }
    }
  }
}

Cloud Router to Azure Connection:

resource "equinix_fabric_connection" "fcr2azure"{
  name = "ConnectionName"
  type = "IP_VC"
  notifications{
    type = "ALL"
    emails = ["example@equinix.com","test1@equinix.com"]
  }
  bandwidth = 50
  order {
    purchase_order_number = "1-323292"
  }
  a_side {
    access_point {
      type = "CLOUD_ROUTER"
      router {
        uuid = "<cloud_router_uuid>"
      }
    }
  }
  z_side {
    access_point {
      type = "SP"
      authentication_key = "<Azure_ExpressRouter_Auth_Key>"
      peering_type = "PRIVATE"
      profile {
        type = "L2_PROFILE"
        uuid = "<Azure_Service_Profile_UUID>"
      }
      location {
        metro_code = "SV"
      }
    }
  }
}

Virtual Device to Azure Connection:

resource "equinix_fabric_connection" "vd2azure" {
  name = "ConnectionName"
  type = "EVPL_VC"
  notifications {
    type   = "ALL"
    emails = ["example@equinix.com", "test1@equinix.com"]
  }
  bandwidth = 50
  order {
    purchase_order_number = "1-323292"
  }
  a_side {
    access_point {
      type = "VD"
      virtual_device {
        type = "EDGE"
        uuid = "<device_uuid>"
      }
      interface {
        type = "CLOUD"
        id = 7
      }
    }
  }
  z_side {
    access_point {
      type = "SP"
      authentication_key = "<Azure_ExpressRouter_Auth_Key>"
      peering_type = "PRIVATE"
      profile {
        type = "L2_PROFILE"
        uuid = "<Azure_Service_Profile_UUID>"
      }
      location {
        metro_code = "SV"
      }
    }
  }
}

Virtual Device to Azure Redundant Connection:

resource "equinix_fabric_connection" "vd2azure_primary" {
  name = "ConnectionName"
  type = "EVPL_VC"
  redundancy { priority = "PRIMARY" }
  notifications {
    type   = "ALL"
    emails = ["example@equinix.com", "test1@equinix.com"]
  }
  bandwidth = 50
  order {
    purchase_order_number = "1-323292"
  }
  a_side {
    access_point {
      type = "VD"
      virtual_device {
        type = "EDGE"
        uuid = "<device_uuid>"
      }
      interface {
        type = "CLOUD"
        id = 7
      }
    }
  }
  z_side {
    access_point {
      type = "SP"
      authentication_key = "<Azure_ExpressRouter_Auth_Key>"
      peering_type = "PRIVATE"
      profile {
        type = "L2_PROFILE"
        uuid = "<Azure_Service_Profile_UUID>"
      }
      location {
        metro_code = "SV"
      }
    }
  }
}

resource "equinix_fabric_connection" "vd2azure_secondary" {
  name = "ConnectionName"
  type = "EVPL_VC"
  redundancy {
    priority = "SECONDARY"
    group = one(equinix_fabric_connection.vd2azure_primary.redundancy).group
  }
  notifications {
    type   = "ALL"
    emails = ["example@equinix.com", "test1@equinix.com"]
  }
  bandwidth = 50
  order {
    purchase_order_number = "1-323292"
  }
  a_side {
    access_point {
      type = "VD"
      virtual_device {
        type = "EDGE"
        uuid = "<device_uuid>"
      }
      interface {
        type = "CLOUD"
        id = 5
      }
    }
  }
  z_side {
    access_point {
      type = "SP"
      authentication_key = "<Azure_ExpressRouter_Auth_Key>"
      peering_type = "PRIVATE"
      profile {
        type = "L2_PROFILE"
        uuid = "<Azure_Service_Profile_UUID>"
      }
      location {
        metro_code = "SV"
      }
    }
  }
}

Cloud Router to Network Connection:

resource "equinix_fabric_connection" "fcr2network"{
  name = "ConnectionName"
  type = "IPWAN_VC"
  notifications{
    type = "ALL"
    emails = ["example@equinix.com","test1@equinix.com"]
  }
  bandwidth = 50
  order {
    purchase_order_number = "1-323292"
  }
  a_side {
    access_point {
      type = "CLOUD_ROUTER"
      router {
        uuid = "<cloud_router_uuid>"
      }
    }
  }
  z_side {
    access_point {
      type = "NETWORK"
      network {
        uuid = "<network_uuid>"
      }
    }
  }
}

Virtual Device to Network Connection:

resource "equinix_fabric_connection" "vd2network" {
  name = "ConnectionName"
  type = "EVPLAN_VC"
  notifications {
    type   = "ALL"
    emails = ["example@equinix.com", "test1@equinix.com"]
  }
  bandwidth = 50
  order {
    purchase_order_number = "1-323292"
  }
  a_side {
    access_point {
      type = "VD"
      virtual_device {
        type = "EDGE"
        uuid = "<device_uuid>"
      }
      interface {
        type = "CLOUD"
        id = 7
      }
    }
  }
  z_side {
    access_point {
      type = "NETWORK"
      network {
        uuid = "<network_uuid>"
      }
    }
  }
}

EPLAN Port to Network Connection:

resource "equinix_fabric_connection" "eplan" {
  name = "ConnectionName"
  type = "EPLAN_VC"
  notifications {
    type   = "ALL"
    emails = ["example@equinix.com", "test1@equinix.com"]
  }
  bandwidth = 50
  order {
    purchase_order_number = "1-323292"
  }
  a_side {
    access_point {
      type = "COLO"
      port {
        uuid = "<aside_port_uuid>"
      }
    }
  }
  z_side {
    access_point {
      type = "NETWORK"
      network {
        uuid = "<network_uuid>"
      }
    }
  }
}

EVPLAN Port to Network Connection:

resource "equinix_fabric_connection" "evplan" {
  name = "ConnectionName"
  type = "EVPLAN_VC"
  notifications {
    type   = "ALL"
    emails = ["example@equinix.com", "test1@equinix.com"]
  }
  bandwidth = 50
  order {
    purchase_order_number = "1-323292"
  }
  a_side {
    access_point {
      type = "COLO"
      port {
        uuid = "<aside_port_uuid>"
      }
      link_protocol {
        type = "DOT1Q"
        vlan_s_tag = "1976"

      }
    }
  }
  z_side {
    access_point {
      type = "NETWORK"
      network {
        uuid = "<network_uuid>"
      }
    }
  }
}

(Metal-Fabric Integration) Metal to AWS EVPL_VC Connection:

resource "equinix_fabric_connection" "metal2aws" {
  name = "ConnectionName"
  type = "EVPLAN_VC"
  notifications {
    type   = "ALL"
    emails = ["example@equinix.com", "test1@equinix.com"]
  }
  bandwidth = 50
  order {
    purchase_order_number = "1-323292"
  }
  a_side {
    access_point {
      type               = "METAL_NETWORK"
      authentication_key = "<metal_authorization_code>"
    }
  }
  z_side {
    access_point {
      type = "SP"
      authentication_key = "<aws_account_id>"
      seller_region = "us-west-1"
      profile {
        type = "L2_PROFILE"
        uuid = "<service_profile_uuid>"
      }
      location {
        metro_code = "SV"
      }
    }
  }
}

(Metal-Fabric Integration) Fabric Cloud Router to Metal IP_VC Connection:

resource "equinix_fabric_connection" "fcr2metal" {
  name = "ConnectionName"
  type = "IP_VC"
  notifications {
    type   = "ALL"
    emails = ["example@equinix.com", "test1@equinix.com"]
  }
  bandwidth = 50
  order {
    purchase_order_number = "1-323292"
  }
  a_side {
    access_point {
      type = "CLOUD_ROUTER"
      router {
        uuid = "<cloud_router_uuid>"
      }
    }
  }
  z_side {
    access_point {
      type               = "METAL_NETWORK"
      authentication_key = "<metal_authorization_code>"
    }
  }
}

Port to Alibaba Connection EVPL_VC Connection:

Step by Step Instructions for the Fabric Port to Fabric Alibaba Profile Connection Example Given Below​

1. Create and Accept the Connection​

  • Create the connection using the Equinix Terraform provider
  • Then manually accept the connection request in the Alibaba Portal for the created physical connection

2. Delete Resources​

  • Run terraform destroy to delete the Alibaba VBR
  • Directly deleting the Equinix Fabric connection, will result in the following error: ERR-UAA-003-00: Deletion for a provisioned connection needs to be initiated from Alibaba Portal
  • Go to the Alibaba Portal to manually terminate and then delete the physical connection
  • This action will automatically delete the connection on the Equinix side, updating its status to Deprovisioned on both Equinix and Provider side
resource "equinix_fabric_connection" "port2alibaba" {
  name = "ConnectionName"
  type = "EVPL_VC"
  notifications {
    type = "ALL"
    emails = ["example@equinix.com", "test1@equinix.com"]
  }
  bandwidth = 50
  redundancy { priority = "PRIMARY" }
  order {
    purchase_order_number = "1-323929"
  }
  a_side {
    access_point {
      type = "COLO"
      port {
        uuid = "<aside_port_uuid>"
      }
      link_protocol {
        type     = "DOT1Q"
        vlan_tag = "2019"
      }
    }
  }
  z_side {
    access_point {
      type               = "SP"
      authentication_key = "<alibaba_account_id>"
      seller_region      = "us-west-1"
      profile {
        type = "L2_PROFILE"
        uuid = "<service_profile_uuid>"
      }
      location {
        metro_code = "SV"
      }
    }
  }
}

Notes:​

Port to IBM Connections could be modified from IBM Service Provider Side by using parameters passed to additional_info field:

  • {"key": "ASN", "value": "1111"}
  • {"key": "Global", "value": "false"}
  • {"key": "BGP_IBM_CIDR", "value": "172.16.0.18/30"}
  • {"key": "BGP_CER_CIDR", "value": "172.16.0.19/30"}

To accept, delete, or upgrade bandwidth for IBM Connections using the 'ibm_dl_gateway_action' resource, you must update the following attribute: For Connection Approval:

  • Use action = "create_gateway_approve" For Bandwidth Upgrade/Downgrade:
  • Use action = "update_attributes_approve" For Connection Deletion:
  • Use action = "delete_gateway_approve"

Schema​

Required​

  • a_side (Block Set, Min: 1, Max: 1) Requester or Customer side connection configuration object of the multi-segment connection (see below for nested schema)
  • bandwidth (Number) Connection bandwidth in Mbps
  • name (String) Connection name. An alpha-numeric 24 characters string which can include only hyphens and underscores
  • notifications (Block List, Min: 1) Preferences for notifications on connection configuration or status changes (see below for nested schema)
  • type (String) Defines the connection type like EVPL_VC, EPL_VC, IPWAN_VC, IP_VC, ACCESS_EPL_VC, EVPLAN_VC, EPLAN_VC, EIA_VC, IA_VC, EC_VC
  • z_side (Block Set, Min: 1, Max: 1) Destination or Provider side connection configuration object of the multi-segment connection (see below for nested schema)

Optional​

Read-Only​

  • account (Set of Object) Customer account information that is associated with this connection (see below for nested schema)
  • change_log (Set of Object) Captures connection lifecycle change information (see below for nested schema)
  • direction (String) Connection directionality from the requester point of view
  • href (String) Connection URI information
  • id (String) The ID of this resource.
  • is_remote (Boolean) Connection property derived from access point locations
  • operation (Set of Object) Connection type-specific operational data (see below for nested schema)
  • state (String) Connection overall state
  • uuid (String) Equinix-assigned connection identifier

Nested Schema for a_side​

Optional:

  • access_point (Block Set, Max: 1) Point of access details (see below for nested schema)
  • additional_info (Block List) Connection side additional information (see below for nested schema)
  • service_token (Block Set, Max: 1) For service token based connections, Service tokens authorize users to access protected resources and services. Resource owners can distribute the tokens to trusted partners and vendors, allowing selected third parties to work directly with Equinix network assets (see below for nested schema)

Nested Schema for a_side.access_point​

Optional:

  • authentication_key (String) Authentication key for provider based connections or Metal-Fabric Integration connections
  • gateway (Block Set, Max: 1, Deprecated) Deprecated gateway Use router attribute instead (see below for nested schema)
  • interface (Block Set, Max: 1) Virtual device interface (see below for nested schema)
  • link_protocol (Block Set, Max: 1) Connection link protocol (see below for nested schema)
  • location (Block Set, Max: 1) Access point location (see below for nested schema)
  • network (Block Set, Max: 1) network access point information (see below for nested schema)
  • peering_type (String) Peering Type- PRIVATE,MICROSOFT,PUBLIC, MANUAL
  • port (Block Set, Max: 1) Port access point information (see below for nested schema)
  • profile (Block Set, Max: 1) Service Profile (see below for nested schema)
  • role (String) Network role
  • router (Block Set, Max: 1) Cloud Router access point information that replaces gateway (see below for nested schema)
  • seller_region (String) Access point seller region
  • type (String) Access point type - COLO, VD, VG, SP, IGW, SUBNET, CLOUD_ROUTER, NETWORK, METAL_NETWORK
  • virtual_device (Block Set, Max: 1) Virtual device (see below for nested schema)

Read-Only:

  • account (Block Set) Account (see below for nested schema)
  • provider_connection_id (String) Provider assigned Connection Id

Nested Schema for a_side.access_point.gateway​

Optional:

  • uuid (String) Equinix-assigned virtual gateway identifier

Read-Only:

  • href (String) Unique Resource Identifier

Nested Schema for a_side.access_point.interface​

Optional:

  • id (Number) id
  • type (String) Interface type
  • uuid (String) Equinix-assigned interface identifier

Optional:

  • type (String) Type of the link protocol - UNTAGGED, DOT1Q, QINQ, EVPN_VXLAN
  • vlan_c_tag (Number) Vlan Customer Tag information, vlanCTag value specified for QINQ connections
  • vlan_s_tag (Number) Vlan Provider Tag information, vlanSTag value specified for QINQ connections
  • vlan_tag (Number) Vlan Tag information, vlanTag value specified for DOT1Q connections

Nested Schema for a_side.access_point.location​

Optional:

  • ibx (String) IBX Code
  • metro_code (String) Access point metro code
  • metro_name (String) Access point metro name
  • region (String) Access point region

Nested Schema for a_side.access_point.network​

Required:

  • uuid (String) Equinix-assigned Network identifier

Read-Only:

  • href (String) Unique Resource Identifier

Nested Schema for a_side.access_point.port​

Optional:

  • uuid (String) Equinix-assigned Port identifier

Read-Only:

  • href (String) Unique Resource Identifier
  • name (String) Port name
  • redundancy (Set of Object) Redundancy Information (see below for nested schema)

Nested Schema for a_side.access_point.port.redundancy​

Read-Only:

  • enabled (Boolean)
  • group (String)
  • priority (String)

Nested Schema for a_side.access_point.profile​

Required:

  • type (String) Service profile type - L2_PROFILE, L3_PROFILE, ECIA_PROFILE, ECMC_PROFILE, IA_PROFILE
  • uuid (String) Equinix assigned service profile identifier

Read-Only:

  • access_point_type_configs (List of Object) Access point config information (see below for nested schema)
  • description (String) User-provided service description
  • href (String) Service Profile URI response attribute
  • name (String) Customer-assigned service profile name

Nested Schema for a_side.access_point.profile.access_point_type_configs​

Read-Only:

  • type (String)
  • uuid (String)

Nested Schema for a_side.access_point.router​

Optional:

  • uuid (String) Equinix-assigned virtual gateway identifier

Read-Only:

  • href (String) Unique Resource Identifier

Nested Schema for a_side.access_point.virtual_device​

Required:

  • uuid (String) Equinix-assigned Virtual Device identifier

Optional:

  • name (String) Customer-assigned Virtual Device Name
  • type (String) Virtual Device type

Read-Only:

  • href (String) Unique Resource Identifier

Nested Schema for a_side.access_point.account​

Read-Only:

  • account_name (String) Legal name of the accountholder.
  • account_number (Number) Equinix-assigned account number.
  • global_cust_id (String) Equinix-assigned ID of the subscriber's parent organization.
  • global_org_id (String) Equinix-assigned ID of the subscriber's parent organization.
  • global_organization_name (String) Equinix-assigned name of the subscriber's parent organization.
  • org_id (Number) Equinix-assigned ID of the subscriber's organization.
  • organization_name (String) Equinix-assigned name of the subscriber's organization.
  • ucm_id (String) Enterprise datastore id

Nested Schema for a_side.additional_info​

Optional:

  • key (String) Additional information key
  • value (String) Additional information value

Nested Schema for a_side.service_token​

Optional:

  • type (String) Token type - VC_TOKEN
  • uuid (String) Equinix-assigned service token identifier

Read-Only:

  • description (String) Service token description
  • href (String) An absolute URL that is the subject of the link's context

Nested Schema for notifications​

Required:

  • emails (List of String) Array of contact emails
  • type (String) Notification Type - ALL,CONNECTION_APPROVAL,SALES_REP_NOTIFICATIONS, NOTIFICATIONS

Optional:

  • send_interval (String) Send interval

Nested Schema for z_side​

Optional:

  • access_point (Block Set, Max: 1) Point of access details (see below for nested schema)
  • additional_info (Block List) Connection side additional information (see below for nested schema)
  • service_token (Block Set, Max: 1) For service token based connections, Service tokens authorize users to access protected resources and services. Resource owners can distribute the tokens to trusted partners and vendors, allowing selected third parties to work directly with Equinix network assets (see below for nested schema)

Nested Schema for z_side.access_point​

Optional:

  • authentication_key (String) Authentication key for provider based connections or Metal-Fabric Integration connections
  • gateway (Block Set, Max: 1, Deprecated) Deprecated gateway Use router attribute instead (see below for nested schema)
  • interface (Block Set, Max: 1) Virtual device interface (see below for nested schema)
  • link_protocol (Block Set, Max: 1) Connection link protocol (see below for nested schema)
  • location (Block Set, Max: 1) Access point location (see below for nested schema)
  • network (Block Set, Max: 1) network access point information (see below for nested schema)
  • peering_type (String) Peering Type- PRIVATE,MICROSOFT,PUBLIC, MANUAL
  • port (Block Set, Max: 1) Port access point information (see below for nested schema)
  • profile (Block Set, Max: 1) Service Profile (see below for nested schema)
  • role (String) Network role
  • router (Block Set, Max: 1) Cloud Router access point information that replaces gateway (see below for nested schema)
  • seller_region (String) Access point seller region
  • type (String) Access point type - COLO, VD, VG, SP, IGW, SUBNET, CLOUD_ROUTER, NETWORK, METAL_NETWORK
  • virtual_device (Block Set, Max: 1) Virtual device (see below for nested schema)

Read-Only:

  • account (Block Set) Account (see below for nested schema)
  • provider_connection_id (String) Provider assigned Connection Id

Nested Schema for z_side.access_point.gateway​

Optional:

  • uuid (String) Equinix-assigned virtual gateway identifier

Read-Only:

  • href (String) Unique Resource Identifier

Nested Schema for z_side.access_point.interface​

Optional:

  • id (Number) id
  • type (String) Interface type
  • uuid (String) Equinix-assigned interface identifier

Optional:

  • type (String) Type of the link protocol - UNTAGGED, DOT1Q, QINQ, EVPN_VXLAN
  • vlan_c_tag (Number) Vlan Customer Tag information, vlanCTag value specified for QINQ connections
  • vlan_s_tag (Number) Vlan Provider Tag information, vlanSTag value specified for QINQ connections
  • vlan_tag (Number) Vlan Tag information, vlanTag value specified for DOT1Q connections

Nested Schema for z_side.access_point.location​

Optional:

  • ibx (String) IBX Code
  • metro_code (String) Access point metro code
  • metro_name (String) Access point metro name
  • region (String) Access point region

Nested Schema for z_side.access_point.network​

Required:

  • uuid (String) Equinix-assigned Network identifier

Read-Only:

  • href (String) Unique Resource Identifier

Nested Schema for z_side.access_point.port​

Optional:

  • uuid (String) Equinix-assigned Port identifier

Read-Only:

  • href (String) Unique Resource Identifier
  • name (String) Port name
  • redundancy (Set of Object) Redundancy Information (see below for nested schema)

Nested Schema for z_side.access_point.port.redundancy​

Read-Only:

  • enabled (Boolean)
  • group (String)
  • priority (String)

Nested Schema for z_side.access_point.profile​

Required:

  • type (String) Service profile type - L2_PROFILE, L3_PROFILE, ECIA_PROFILE, ECMC_PROFILE, IA_PROFILE
  • uuid (String) Equinix assigned service profile identifier

Read-Only:

  • access_point_type_configs (List of Object) Access point config information (see below for nested schema)
  • description (String) User-provided service description
  • href (String) Service Profile URI response attribute
  • name (String) Customer-assigned service profile name

Nested Schema for z_side.access_point.profile.access_point_type_configs​

Read-Only:

  • type (String)
  • uuid (String)

Nested Schema for z_side.access_point.router​

Optional:

  • uuid (String) Equinix-assigned virtual gateway identifier

Read-Only:

  • href (String) Unique Resource Identifier

Nested Schema for z_side.access_point.virtual_device​

Required:

  • uuid (String) Equinix-assigned Virtual Device identifier

Optional:

  • name (String) Customer-assigned Virtual Device Name
  • type (String) Virtual Device type

Read-Only:

  • href (String) Unique Resource Identifier

Nested Schema for z_side.access_point.account​

Read-Only:

  • account_name (String) Legal name of the accountholder.
  • account_number (Number) Equinix-assigned account number.
  • global_cust_id (String) Equinix-assigned ID of the subscriber's parent organization.
  • global_org_id (String) Equinix-assigned ID of the subscriber's parent organization.
  • global_organization_name (String) Equinix-assigned name of the subscriber's parent organization.
  • org_id (Number) Equinix-assigned ID of the subscriber's organization.
  • organization_name (String) Equinix-assigned name of the subscriber's organization.
  • ucm_id (String) Enterprise datastore id

Nested Schema for z_side.additional_info​

Optional:

  • key (String) Additional information key
  • value (String) Additional information value

Nested Schema for z_side.service_token​

Optional:

  • type (String) Token type - VC_TOKEN
  • uuid (String) Equinix-assigned service token identifier

Read-Only:

  • description (String) Service token description
  • href (String) An absolute URL that is the subject of the link's context

Nested Schema for order​

Optional:

  • billing_tier (String) Billing tier for connection bandwidth
  • order_id (String) Order Identification
  • order_number (String) Order Reference Number
  • purchase_order_number (String) Purchase order number
  • term_length (Number) Term length in months; valid values are 1, 12, 24, 36 where 1 is the default value (for on-demand case)

Nested Schema for project​

Optional:

  • project_id (String) Project Id

Read-Only:

  • href (String) Unique Resource URL

Nested Schema for redundancy​

Optional:

  • group (String) Redundancy group identifier (Use the redundancy.0.group UUID of primary connection; e.g. one(equinix_fabric_connection.primary_port_connection.redundancy).group or equinix_fabric_connection.primary_port_connection.redundancy.0.group)
  • priority (String) Connection priority in redundancy group - PRIMARY, SECONDARY

Nested Schema for timeouts​

Optional:

  • create (String)
  • delete (String)
  • read (String)
  • update (String)

Nested Schema for account​

Read-Only:

  • account_name (String)
  • account_number (Number)
  • global_cust_id (String)
  • global_org_id (String)
  • global_organization_name (String)
  • org_id (Number)
  • organization_name (String)
  • ucm_id (String)

Nested Schema for change_log​

Read-Only:

  • created_by (String)
  • created_by_email (String)
  • created_by_full_name (String)
  • created_date_time (String)
  • deleted_by (String)
  • deleted_by_email (String)
  • deleted_by_full_name (String)
  • deleted_date_time (String)
  • updated_by (String)
  • updated_by_email (String)
  • updated_by_full_name (String)
  • updated_date_time (String)

Nested Schema for operation​

Read-Only:

Nested Schema for operation.errors​

Read-Only:

  • additional_info (List of Object) (see below for nested schema)
  • correlation_id (String)
  • details (String)
  • error_code (String)
  • error_message (String)
  • help (String)

Nested Schema for operation.errors.additional_info​

Read-Only:

  • property (String)
  • reason (String)
Was this page helpful?