Aviso de Descontinuação O Equinix Metal alcance ao fim de sua vida útil em 30 de junho de 2026 Todos os recursos do Metal serão removidos na versão 5.0.0 deste provedor. Use a versão 4.x deste provedor para continuar utilizando-o após o encerramento das atividades. Consulte https://docs.equinix.com/metal/ para obter mais informações.

equinix_metal_vrf (Recurso)

Utilize este recurso para gerenciar um VRF.

Consulte a [documentação de Roteamento e Encaminhamento Virtual para obter detalhes do produto e material de referência da API .

Exemplo de uso

Crie uma VRF na rede metropolitana desejada e projete-a com os intervalos de IP que você deseja que a VRF roteie e encaminhe.

resource "equinix_metal_project" "example" {
    name = "example"
}

resource "equinix_metal_vrf" "example" {
    description = "VRF with ASN 65000 and a pool of address space that includes 192.168.100.0/25"
    name        = "example-vrf"
    metro       = "da"
    local_asn   = "65000"
    ip_ranges   = ["192.168.100.0/25", "192.168.200.0/25"]
    project_id  = equinix_metal_project.example.id
}

Crie reservas de IP e atribua-as a um recurso do Metal Gateway. O Gateway receberá o primeiro endereço do bloco.

resource "equinix_metal_reserved_ip_block" "example" {
    description = "Reserved IP block (192.168.100.0/29) taken from on of the ranges in the VRF's pool of address space."
    project_id  = equinix_metal_project.example.id
    metro       = equinix_metal_vrf.example.metro
    type        = "vrf"
    vrf_id      = equinix_metal_vrf.example.id
    cidr        = 29
    network     = "192.168.100.0"
}

resource "equinix_metal_vlan" "example" {
    description = "A VLAN for Layer2 and Hybrid Metal devices"
    metro       = equinix_metal_vrf.example.metro
    project_id  = equinix_metal_project.example.id
}

resource "equinix_metal_gateway" "example" {
    project_id        = equinix_metal_project.example.id
    vlan_id           = equinix_metal_vlan.example.id
    ip_reservation_id = equinix_metal_reserved_ip_block.example.id
}

Conecte um circuito virtual de uma conexão metálica dedicada ao gateway metálico.

data "equinix_metal_connection" "example" {
    connection_id = var.metal_dedicated_connection_id
}

resource "equinix_metal_virtual_circuit" "example" {
    name          = "example-vc"
    description   = "Virtual Circuit"
    connection_id = data.equinix_metal_connection.example.id
    project_id    = equinix_metal_project.example.id
    port_id       = data.equinix_metal_connection.example.ports[0].id
    nni_vlan      = 1024
    vrf_id        = equinix_metal_vrf.example.id
    peer_asn      = 65530
    subnet        = "192.168.100.16/31"
    metal_ip      = "192.168.100.16"
    customer_ip   = "192.168.100.17"
}

Esquema

Obrigatório

• metro (String) ID ou código do área metropolitana onde o VRF será implantado
• name (String) Nome do VRF fornecido pelo usuário, exclusivo para o projeto
• project_id (String) ID do projeto onde o VRF será implantado

Opcional

• description (String) Descrição do VRF
• ip_ranges (Conjunto de Strings) Todos os intervalos de endereços IPv4 e IPv6 que estarão disponíveis para os pares BGP . Os endereços IPv4 devem ser /8 ou menores, com um tamanho mínimo de /29. Os endereços IPv6 devem ser /56 ou menores, com um tamanho mínimo de /64. Os intervalos não devem se sobrepor a outros intervalos dentro do VRF.
• local_asn (Número) O ASN de 4 bytes definido no VRF.

Somente leitura

• id (String) O ID deste recurso.

Importar

Este recurso pode ser importado usando um ID VRF existente:

terraform import equinix_metal_vrf {existing_id}