Aviso de Descontinuação O Equinix Metal alcance ao fim de sua vida útil em 30 de junho de 2026 Todos os recursos do Metal serão removidos na versão 5.0.0 deste provedor. Use a versão 4.x deste provedor para continuar utilizando-o após o encerramento das atividades. Consulte https://docs.equinix.com/metal/ para obter mais informações.

equinix_metal_port_vlan_attachment (Recurso)

Fornece um recurso para conectar portas de dispositivos a VLANs.

O dispositivo e a VLAN devem estar na mesma rede metropolitana.

Se você precisar que este recurso adicione a porta de volta ao vínculo após a remoção, defina force_bond = true.

Para saber mais sobre redes de camada 2 no Equinix Metal, consulte

• https://docs.equinix.com/metal/layer2-networking/overview/

Exemplo de uso

Tipo de rede híbrida

resource "equinix_metal_vlan" "test" {
  description = "VLAN in New York"
  metro       = "ny"
  project_id  = local.project_id
}

resource "equinix_metal_device" "test" {
  hostname         = "test"
  plan             = "c3.small.x86"
  metro            = "ny"
  operating_system = "ubuntu_24_04"
  billing_cycle    = "hourly"
  project_id       = local.project_id
}

resource "equinix_metal_device_network_type" "test" {
  device_id = equinix_metal_device.test.id
  type      = "hybrid"
}

resource "equinix_metal_port_vlan_attachment" "test" {
  device_id = equinix_metal_device_network_type.test.id
  port_name = "eth1"
  vlan_vnid = equinix_metal_vlan.test.vxlan
}

Rede de camada 2

resource "equinix_metal_device" "test" {
  hostname         = "test"
  plan             = "c3.small.x86"
  metro            = "ny"
  operating_system = "ubuntu_24_04"
  billing_cycle    = "hourly"
  project_id       = local.project_id
}

resource "equinix_metal_device_network_type" "test" {
  device_id = equinix_metal_device.test.id
  type      = "layer2-individual"
}

resource "equinix_metal_vlan" "test1" {
  description = "VLAN in New York"
  metro       = "ny"
  project_id  = local.project_id
}

resource "equinix_metal_vlan" "test2" {
  description = "VLAN in New Jersey"
  metro       = "ny"
  project_id  = local.project_id
}

resource "equinix_metal_port_vlan_attachment" "test1" {
  device_id = equinix_metal_device_network_type.test.id
  vlan_vnid = equinix_metal_vlan.test1.vxlan
  port_name = "eth1"
}

resource "equinix_metal_port_vlan_attachment" "test2" {
  device_id  = equinix_metal_device_network_type.test.id
  vlan_vnid  = equinix_metal_vlan.test2.vxlan
  port_name  = "eth1"
  native     = true
  depends_on = ["equinix_metal_port_vlan_attachment.test1"]
}

Referência do argumento

Os seguintes argumentos são suportados:

• device_id - (Obrigatório) ID do dispositivo a ser atribuído à VLAN.
• port_name - (Obrigatório) Nome da porta de rede a ser atribuída à VLAN.
• vlan_vnid - (Obrigatório) Identificador de rede VXLAN.
• force_bond - (Opcional) Adiciona a porta de volta ao vínculo quando este recurso for removido. O padrão é false.
• native - (Opcional) Marque esta VLAN como uma VLAN nativa na porta. Isso só pode ser usado se esta atribuição atribuir uma segunda ou mais VLAN à porta. Para garantir que esta conexão não seja a primeira em uma porta, você pode usar depends_on apontando para outro equinix_metal_port_vlan_attachment, assim como no exemplo layer2-individual acima.

Referência de atributo

Além de todos os argumentos acima, os seguintes atributos são exportados:

• id - UUID da porta do dispositivo usada na atribuição.
• vlan_id - UUID do recurso da API VLAN .
• port_id - UUID da porta do dispositivo .