Ir para o conteúdo principal

Aviso de Descontinuação O Equinix Metal alcance ao fim de sua vida útil em 30 de junho de 2026 Todos os recursos do Metal serão removidos na versão 5.0.0 deste provedor. Use a versão 4.x deste provedor para continuar utilizando-o após o encerramento das atividades. Consulte https://docs.equinix.com/metal/ para obter mais informações.

equinix_metal_connection (Recurso)

Use este recurso para solicitar a criação de um ativo de interconexão para se conectar com outras partes usando Equinix Fabric - interconexões definidas por software .

Exemplo de uso​

Conexão Virtual Compartilhada Faturada da Fabric - Conexão não redundante da sua própria porta Equinix Fabric para a Equinix Metal.​

resource "equinix_metal_vlan" "example" {
  project_id = "<metal_project_id>"
  metro      = "FR"
}

resource "equinix_metal_connection" "example" {
  name               = "tf-metal-from-port"
  project_id         = "<metal_project_id>"
  type               = "shared"
  redundancy         = "primary"
  metro              = "FR"
  speed              = "200Mbps"
  service_token_type = "z_side"
  contact_email      = "username@example.com"
  vlans              = [equinix_metal_vlan.example.vxlan]
}

data "equinix_fabric_ports" "a_side" {
  filters {
    name = "<name_of_port||port_prefix>"
  }
}

resource "equinix_fabric_connection" "example" {
  name      = "tf-metal-from-port"
  type      = "EVPL_VC"
  bandwidth = "200"
  notifications {
    type   = "ALL"
    emails = ["username@example.com"]
  }
  order { purchase_order_number = "1-323292" }
  project { project_id = "<fabric_project_id>" }
  a_side {
    access_point {
      type = "COLO"
      port {
        uuid = data.equinix_fabric_ports.a_side.data.0.uuid
      }
      link_protocol {
        type     = "DOT1Q"
        vlan_tag = 1234
      }
    }
  }
  z_side {
    service_token {
      uuid = equinix_metal_connection.example.service_tokens.0.id
    }
  }
}

-> NOTA: Existe um módulo Terraform Equinix Fabric L2 Connection To Equinix Metal disponível com exemplos completos de conexões de Portas Fabric, dispositivos de Network Edge ou tokens de serviço. Confira o [exemplo para conexão compartilhada com token de serviço do lado Z.

Conexão Virtual Compartilhada Faturada pela Fabric - Conexão não redundante do seu próprio dispositivo Network Edge para o Equinix Metal.​

resource "equinix_metal_vrf" "example" {
  name       = "tf-metal-from-ne"
  metro      = "FR"
  local_asn  = "65001"
  ip_ranges  = ["10.99.1.0/24"]
  project_id = equinix_metal_project.test.id
}

resource "equinix_metal_connection" "example" {
  name               = "tf-metal-from-ne"
  project_id         = "<metal_project_id>"
  type               = "shared"
  redundancy         = "primary"
  metro              = "FR"
  speed              = "200Mbps"
  service_token_type = "z_side"
  contact_email      = "username@example.com"
  vrfs               = [equinix_metal_vrf.example.vxlan]
}

resource "equinix_fabric_connection" "example" {
  name      = "tf-metal-from-ne"
  type      = "EVPL_VC"
  bandwidth = "200"
  notifications {
    type   = "ALL"
    emails = ["username@example.com"]
  }
  order { purchase_order_number = "1-323292" }
  project { project_id = "<fabric_project_id>" }
  a_side {
    access_point {
      type = "VD"
      virtual_device {
        type = "EDGE"
        uuid = equinix_network_device.example.id
      }
    }
  }
  z_side {
    service_token {
      uuid = equinix_metal_connection.example.service_tokens.0.id
    }
  }
}

Conexão virtual compartilhada faturada do Fabric - Conexão não redundante do roteador Equinix Fabric Cloud para o Equinix Metal.​

resource "equinix_metal_vlan" "example1" {
  project_id = "<metal_project_id>"
  metro      = "SV"
}

resource "equinix_metal_connection" "example" {
  name          = "tf-metal-from-fcr"
  project_id    = "<metal_project_id>"
  metro         = "SV"
  redundancy    = "primary"
  type          = "shared_port_vlan"
  contact_email = "username@example.com"
  speed         = "200Mbps"
  vlans         = [equinix_metal_vlan.example1.vxlan]
}

resource "equinix_fabric_connection" "example" {
  name      = "tf-metal-from-fcr"
  type      = "IP_VC"
  bandwidth = "200"
  notifications {
    type   = "ALL"
    emails = ["username@example.com"]
  }
  project { project_id = "<fabric_project_id>" }
  a_side {
    access_point {
      type = "CLOUD_ROUTER"
      router {
        uuid = equinix_fabric_cloud_router.example.id
      }
    }
  }
  z_side {
    access_point {
      type               = "METAL_NETWORK"
      authentication_key = equinix_metal_connection.example.authorization_code
    }
  }
}

Conexão Virtual Compartilhada com Cobrança em Metal - Conexão redundante do Equinix Metal para um Provedor de Serviços em Nuvem​

resource "equinix_metal_connection" "example" {
  name               = "tf-metal-2-azure"
  project_id         = "<metal_project_id>"
  type               = "shared"
  redundancy         = "redundant"
  metro              = "SV"
  speed              = "1Gbps"
  service_token_type = "a_side"
  contact_email      = "username@example.com"
}

data "equinix_fabric_service_profiles" "zside" {
  filter {
    property = "/name"
    operator = "="
    values   = ["Azure ExpressRoute"]
  }
}

resource "equinix_fabric_connection" "example_primary" {
  name      = "tf-metal-2-azure-pri"
  type      = "EVPL_VC"
  bandwidth = azurerm_express_route_circuit.example.bandwidth_in_mbps
  redundancy { priority = "PRIMARY" }
  notifications {
    type   = "ALL"
    emails = ["username@example.com"]
  }
  project { project_id = "<fabric_project_id>" }
  a_side {
    service_token {
      uuid = equinix_metal_connection.example.service_tokens.0.id
    }
  }
  z_side {
    access_point {
      type               = "SP"
      authentication_key = azurerm_express_route_circuit.example.service_key
      profile {
        type = "L2_PROFILE"
        uuid = data.equinix_fabric_service_profiles.zside.id
      }
      location {
        metro_code = "SV"
      }
    }
  }
}

resource "equinix_fabric_connection" "example_secondary" {
  name      = "tf-metal-2-azure-sec"
  type      = "EVPL_VC"
  bandwidth = azurerm_express_route_circuit.example.bandwidth_in_mbps
  redundancy {
    priority = "SECONDARY"
    group    = one(equinix_fabric_connection.example_primary.redundancy).group
  }
  notifications {
    type   = "ALL"
    emails = ["username@example.com"]
  }
  project { project_id = "<fabric_project_id>" }
  a_side {
    service_token {
      uuid = equinix_metal_connection.example.service_tokens.1.id
    }
  }
  z_side {
    access_point {
      type               = "SP"
      authentication_key = azurerm_express_route_circuit.example.service_key
      profile {
        type = "L2_PROFILE"
        uuid = data.equinix_fabric_service_profiles.zside.id
      }
      location {
        metro_code = "SV"
      }
    }
  }
}

-> NOTA: Existem vários módulos Terraform de conexão L2 do Equinix Fabric disponíveis com exemplos completos de conexões de Portas do Fabric, dispositivos de Network Edge ou tokens de serviço para os provedores de serviços em nuvem mais populares. Confira os exemplos para conexão compartilhada do Equinix Metal com token de serviço do lado A incluído em cada um deles: AWS, Azure, Google Cloud, IBM Cloud, Oracle Cloud e Alibaba Cloud.

Conexão virtual compartilhada com cobrança em Metal - Conexão não redundante do Equinix Metal para sua própria porta Equinix Fabric.​

resource "equinix_metal_connection" "example" {
  name               = "tf-metal-2-port"
  project_id         = "<metal_project_id>"
  type               = "shared"
  redundancy         = "redundant"
  metro              = "FR"
  speed              = "1Gbps"
  service_token_type = "a_side"
  contact_email      = "username@example.com"
}

data "equinix_fabric_ports" "a_side" {
  filters {
    name = "<name_of_port||port_prefix>"
  }
}

resource "equinix_fabric_connection" "example" {
  name = "tf-metal-2-port"
  type = "EVPL_VC"
  notifications {
    type   = "ALL"
    emails = ["username@example.com"]
  }
  project {
    project_id = "<fabric_project_id>"
  }
  bandwidth = "100"
  order {
    purchase_order_number = "1-323292"
  }
  a_side {
    service_token {
      uuid = equinix_metal_connection.example.service_tokens.0.id
    }
  }
  z_side {
    access_point {
      type = "COLO"
      port {
        uuid = data.equinix_fabric_ports.a_side.data.0.uuid
      }
      link_protocol {
        type     = "DOT1Q"
        vlan_tag = 1234
      }
    }
  }
}

Esquema​

Obrigatório​

  • name (String) Nome do recurso de conexão
  • redundancy (String) redundância de conexão - redundante ou primária
  • type (String) Tipo de conexão - dedicado, compartilhada ou shared_port_vlan

Opcional​

  • contact_email (String) O e-mail preferencial usado para comunicação e notificações sobre a interconexão do Equinix Fabric.
  • description (String) Descrição do recurso de conexão
  • facility (String, Obsoleto) Instalação onde a conexão será criada
  • metro (String) área metropolitana onde a conexão será criada
  • mode (String) Modo para conexões em instalações IBX com o tipo dedicado - padrão ou túnel
  • organization_id (String) ID da organização responsável pela conexão. Aplicável ao tipo "dedicado".
  • project_id (String) ID do projeto ao qual a conexão está vinculada. Obrigatório para o tipo "compartilhado".
  • service_token_type (String) Usado apenas com conexão compartilhada. Tipo de token de serviço a ser usado para a conexão, a_side ou z_side.
  • speed (String) Velocidade de conexão - Os valores devem estar no formato ' 'Mbps' ou ' 'Gbps', por exemplo, '100 Mbps' ou '50 Gbps'. Os valores suportados reais dependerão do tipo de conexão e se a conexão usa VLANs ou VRF.
  • tags (Lista de Strings) Etiquetas associadas à conexão
  • vlans (Lista de Números) Usado apenas com conexão compartilhada. VLANs para conectar. Passe uma VLAN para conexão primária/única e duas VLANs para conexão redundante.
  • vrfs (Lista de Strings) Usado apenas com conexão compartilhada. VRFs para anexar. Passe uma VRF para conexão primária/única e duas VRFs para conexão redundante.

Somente leitura​

  • authorization_code (String) Usado apenas com conexão compartilhada do Fabric . O Fabric usa esse token para poder fornecer informações mais detalhadas sobre a extremidade Metal da rede ao visualizar recursos de dentro do Fabric.
  • id (String) O identificador único do recurso
  • ports (Lista de Objetos) Lista de portas de conexão - primária (ports[0]) e secundária (ports[1]) (veja [abaixo para esquema aninhado](#nestedatt-- portas))
  • service_tokens (Lista de Objetos) Usado apenas com conexão compartilhada. Lista de tokens de serviço necessários para continuar o processo de configuração com equinix_fabric_connection ou a partir do Portal do Equinix Fabric (consulte abaixo para o esquema aninhado)
  • status (String) Status do recurso de conexão
  • token (String, Obsoleto) Usado apenas com conexão compartilhada. O token do Fabric é necessário para continuar o processo de configuração com equinix_fabric_connection ou no Portal do Equinix Fabric

Esquema aninhado para ports​

Somente leitura:

  • id (String)
  • link_status (String)
  • name (String)
  • role (String)
  • speed (Número)
  • status (String)
  • virtual_circuit_ids (Lista de strings)

Esquema aninhado para service_tokens​

Somente leitura:

  • expires_at (String)
  • id (String)
  • max_allowed_speed (String)
  • role (String)
  • state (String)
  • type (String)
Esta página foi útil?