~>非推奨のお知らせ Equinix Metalは、2026年6月30日 でサポートを終了します。すべてのMetalリソースは、このプロバイダのバージョン5.0.0で削除されます。廃止までの継続利用には、このプロバイダのバージョン4.xをご利用ください。詳細は https://docs.equinix.com/metal/ をご覧ください。

equinix_metal_vrf（リソース）

このリソースを使用してVRFを管理します。

製品の詳細と API リファレンス資料については、[Virtual Routing and Forwarding documentation を参照してください。

使用例

希望のメトロでVRFを作成し、VRFにルーティングおよびフォワードさせたい任意のIPレンジでプロジェクトを作成します。

resource "equinix_metal_project" "example" {
    name = "example"
}

resource "equinix_metal_vrf" "example" {
    description = "VRF with ASN 65000 and a pool of address space that includes 192.168.100.0/25"
    name        = "example-vrf"
    metro       = "da"
    local_asn   = "65000"
    ip_ranges   = ["192.168.100.0/25", "192.168.200.0/25"]
    project_id  = equinix_metal_project.example.id
}

IP予約を作成し、メタルゲートウェイリソースに割り当てます。ゲートウェイにはブロック内の最初のアドレスが割り当てられます。

resource "equinix_metal_reserved_ip_block" "example" {
    description = "Reserved IP block (192.168.100.0/29) taken from on of the ranges in the VRF's pool of address space."
    project_id  = equinix_metal_project.example.id
    metro       = equinix_metal_vrf.example.metro
    type        = "vrf"
    vrf_id      = equinix_metal_vrf.example.id
    cidr        = 29
    network     = "192.168.100.0"
}

resource "equinix_metal_vlan" "example" {
    description = "A VLAN for Layer2 and Hybrid Metal devices"
    metro       = equinix_metal_vrf.example.metro
    project_id  = equinix_metal_project.example.id
}

resource "equinix_metal_gateway" "example" {
    project_id        = equinix_metal_project.example.id
    vlan_id           = equinix_metal_vlan.example.id
    ip_reservation_id = equinix_metal_reserved_ip_block.example.id
}

専用メタル接続からメタルゲートウェイに仮想サーキットをアタッチします。

data "equinix_metal_connection" "example" {
    connection_id = var.metal_dedicated_connection_id
}

resource "equinix_metal_virtual_circuit" "example" {
    name          = "example-vc"
    description   = "Virtual Circuit"
    connection_id = data.equinix_metal_connection.example.id
    project_id    = equinix_metal_project.example.id
    port_id       = data.equinix_metal_connection.example.ports[0].id
    nni_vlan      = 1024
    vrf_id        = equinix_metal_vrf.example.id
    peer_asn      = 65530
    subnet        = "192.168.100.16/31"
    metal_ip      = "192.168.100.16"
    customer_ip   = "192.168.100.17"
}

スキーマ

必須

• metro (String) VRF が配置されるメトロ ID またはコード。
• name （文字列） プロジェクト固有の VRF 名。
• project_id (String) VRF が配置されるプロジェクト ID

オプション

• description (文字列) VRF の説明
• ip_ranges （文字列のセット） BGP ピアが使用できるすべての IPv4 および IPv6 レンジ。IPv4アドレスは/8以下、最小サイズは/29。IPv6 アドレスは /56 以下、最小サイズは /64 です。レンジは VRF 内の他のレンジと重複してはいけません。
• local_asn (番号) VRF に設定されている 4 バイトの ASN。

読み取り専用

• id （文字列） このリソースの ID。

インポート

このリソースは、既存の VRF ID を使用してインポートできます：

terraform import equinix_metal_vrf {existing_id}