~>非推奨のお知らせ Equinix Metalは、2026年6月30日 でサポートを終了します。すべてのMetalリソースは、このプロバイダのバージョン5.0.0で削除されます。廃止までの継続利用には、このプロバイダのバージョン4.xをご利用ください。詳細は https://docs.equinix.com/metal/ をご覧ください。

equinix_metal_port_vlan_attachment（リソース）

デバイス・ポートを VLAN にアタッチするためのリソースを提供します。

デバイスとVLANは同じメトロでなければなりません。

削除時にポートをボンドに戻すためにこのリソースが必要な場合は、force_bond = trueを設定します。

Equinix Metalのレイヤー2ネットワークについては、次のサイトを参照してください。

• https://docs.equinix.com/metal/layer2-networking/overview/

使用例

ハイブリッドネットワークタイプ

resource "equinix_metal_vlan" "test" {
  description = "VLAN in New York"
  metro       = "ny"
  project_id  = local.project_id
}

resource "equinix_metal_device" "test" {
  hostname         = "test"
  plan             = "c3.small.x86"
  metro            = "ny"
  operating_system = "ubuntu_24_04"
  billing_cycle    = "hourly"
  project_id       = local.project_id
}

resource "equinix_metal_device_network_type" "test" {
  device_id = equinix_metal_device.test.id
  type      = "hybrid"
}

resource "equinix_metal_port_vlan_attachment" "test" {
  device_id = equinix_metal_device_network_type.test.id
  port_name = "eth1"
  vlan_vnid = equinix_metal_vlan.test.vxlan
}

レイヤ2ネットワーク

resource "equinix_metal_device" "test" {
  hostname         = "test"
  plan             = "c3.small.x86"
  metro            = "ny"
  operating_system = "ubuntu_24_04"
  billing_cycle    = "hourly"
  project_id       = local.project_id
}

resource "equinix_metal_device_network_type" "test" {
  device_id = equinix_metal_device.test.id
  type      = "layer2-individual"
}

resource "equinix_metal_vlan" "test1" {
  description = "VLAN in New York"
  metro       = "ny"
  project_id  = local.project_id
}

resource "equinix_metal_vlan" "test2" {
  description = "VLAN in New Jersey"
  metro       = "ny"
  project_id  = local.project_id
}

resource "equinix_metal_port_vlan_attachment" "test1" {
  device_id = equinix_metal_device_network_type.test.id
  vlan_vnid = equinix_metal_vlan.test1.vxlan
  port_name = "eth1"
}

resource "equinix_metal_port_vlan_attachment" "test2" {
  device_id  = equinix_metal_device_network_type.test.id
  vlan_vnid  = equinix_metal_vlan.test2.vxlan
  port_name  = "eth1"
  native     = true
  depends_on = ["equinix_metal_port_vlan_attachment.test1"]
}

引数リファレンス

以下の引数をサポートしています：

• device_id - （必須）VLAN に割り当てるデバイスの ID。
• port_name - （必須）VLANに割り当てるネットワークポート名。
• vlan_vnid - （必須）VXLAN ネットワーク識別子。
• force_bond - (オプション) このリソースが削除されたときにポートをボンドに追加します。デフォルトはfalseです。
• native - （オプション）この VLAN をポートのネイティブ VLAN としてマークします。これは、この割り当てがポートに 2 番目以上の VLAN を割り当てる場合にのみ使用できます。このアタッチメントがポート上で最初にならないようにするには、上記のレイヤ 2-individual の例と同じように、別の equinix_metal_port_vlan_attachment を指す depends_on を使用します。

属性参照

上記のすべての引数に加えて、以下の属性がエクスポートされます：

• id - 割り当てに使用されるデバイスポートの UUID。
• vlan_id - VLAN API リソースの UUID。
• port_id - デバイスポートの UUID。