~> Deprecation Notice Equinix Metal arrivera en fin de vie le 30 juin 2026. Toutes les ressources Metal seront supprimées dans la version 5.0.0 de ce fournisseur. Utilisez la version 4.x de ce fournisseur pour continuer à l'utiliser jusqu'à la fin de sa durée de vie. Consultez https://docs.equinix.com/metal/ pour plus d'informations.

equinix_metal_vrf (Ressource)

Utilisez cette ressource pour gérer un VRF.

Consultez la [documentation sur le routage et le transfert virtuels pour obtenir des détails sur le produit et des documents de référence sur l'API.

Exemple d'utilisation

Créez un VRF dans le métro de votre choix et projetez toutes les plages IP que vous souhaitez que le VRF achemine et transfère.

resource "equinix_metal_project" "example" {
    name = "example"
}

resource "equinix_metal_vrf" "example" {
    description = "VRF with ASN 65000 and a pool of address space that includes 192.168.100.0/25"
    name        = "example-vrf"
    metro       = "da"
    local_asn   = "65000"
    ip_ranges   = ["192.168.100.0/25", "192.168.200.0/25"]
    project_id  = equinix_metal_project.example.id
}

Créez des réservations d'IP et attribuez-les à une ressource Metal Gateway. La première adresse du bloc sera attribuée à la passerelle.

resource "equinix_metal_reserved_ip_block" "example" {
    description = "Reserved IP block (192.168.100.0/29) taken from on of the ranges in the VRF's pool of address space."
    project_id  = equinix_metal_project.example.id
    metro       = equinix_metal_vrf.example.metro
    type        = "vrf"
    vrf_id      = equinix_metal_vrf.example.id
    cidr        = 29
    network     = "192.168.100.0"
}

resource "equinix_metal_vlan" "example" {
    description = "A VLAN for Layer2 and Hybrid Metal devices"
    metro       = equinix_metal_vrf.example.metro
    project_id  = equinix_metal_project.example.id
}

resource "equinix_metal_gateway" "example" {
    project_id        = equinix_metal_project.example.id
    vlan_id           = equinix_metal_vlan.example.id
    ip_reservation_id = equinix_metal_reserved_ip_block.example.id
}

Attachez un circuit virtuel d'une connexion Metal dédiée à la passerelle Metal.

data "equinix_metal_connection" "example" {
    connection_id = var.metal_dedicated_connection_id
}

resource "equinix_metal_virtual_circuit" "example" {
    name          = "example-vc"
    description   = "Virtual Circuit"
    connection_id = data.equinix_metal_connection.example.id
    project_id    = equinix_metal_project.example.id
    port_id       = data.equinix_metal_connection.example.ports[0].id
    nni_vlan      = 1024
    vrf_id        = equinix_metal_vrf.example.id
    peer_asn      = 65530
    subnet        = "192.168.100.16/31"
    metal_ip      = "192.168.100.16"
    customer_ip   = "192.168.100.17"
}

Schéma

Exigée

• metro (String) Metro ID ou Code où le VRF sera déployé
• name (String) Nom du VRF fourni par l'utilisateur, unique pour le projet.
• project_id (Chaîne) ID du projet où le VRF sera déployé

En option

• description (Chaîne) Description du VRF
• ip_ranges (ensemble de chaînes) Toutes les plages IPv4 et IPv6 qui seront disponibles pour les homologues BGP. Les adresses IPv4 doivent être /8 ou inférieures, avec une taille minimale de /29. Les adresses IPv6 doivent être /56 ou inférieures, avec une taille minimale de /64. Les plages ne doivent pas chevaucher d'autres plages au sein du VRF.
• local_asn (Nombre) Le jeu d'ASN de 4 octets sur le VRF.

En lecture seule

• id (Chaîne) L'identifiant de cette ressource.

Importer

Cette ressource peut être importée à l'aide d'un ID VRF existant :

terraform import equinix_metal_vrf {existing_id}