~> Deprecation Notice Equinix Metal arrivera en fin de vie le 30 juin 2026. Toutes les ressources Metal seront supprimées dans la version 5.0.0 de ce fournisseur. Utilisez la version 4.x de ce fournisseur pour continuer à l'utiliser jusqu'à la fin de sa durée de vie. Consultez https://docs.equinix.com/metal/ pour plus d'informations.

equinix_metal_port_vlan_attachment (Ressource)

Fournit une ressource pour attacher les ports de périphériques aux VLAN.

L'appareil et le VLAN doivent se trouver dans le même métro.

Si vous avez besoin de cette ressource pour ajouter le port à la liaison lors de son retrait, définissez force_bond = true.

Pour en savoir plus sur la mise en réseau de couche 2 dans le Metal d'Equinix, reportez-vous à .

• https://docs.equinix.com/metal/layer2-networking/overview/

Exemple d'utilisation

Type de réseau hybride

resource "equinix_metal_vlan" "test" {
  description = "VLAN in New York"
  metro       = "ny"
  project_id  = local.project_id
}

resource "equinix_metal_device" "test" {
  hostname         = "test"
  plan             = "c3.small.x86"
  metro            = "ny"
  operating_system = "ubuntu_24_04"
  billing_cycle    = "hourly"
  project_id       = local.project_id
}

resource "equinix_metal_device_network_type" "test" {
  device_id = equinix_metal_device.test.id
  type      = "hybrid"
}

resource "equinix_metal_port_vlan_attachment" "test" {
  device_id = equinix_metal_device_network_type.test.id
  port_name = "eth1"
  vlan_vnid = equinix_metal_vlan.test.vxlan
}

Réseau de couche 2

resource "equinix_metal_device" "test" {
  hostname         = "test"
  plan             = "c3.small.x86"
  metro            = "ny"
  operating_system = "ubuntu_24_04"
  billing_cycle    = "hourly"
  project_id       = local.project_id
}

resource "equinix_metal_device_network_type" "test" {
  device_id = equinix_metal_device.test.id
  type      = "layer2-individual"
}

resource "equinix_metal_vlan" "test1" {
  description = "VLAN in New York"
  metro       = "ny"
  project_id  = local.project_id
}

resource "equinix_metal_vlan" "test2" {
  description = "VLAN in New Jersey"
  metro       = "ny"
  project_id  = local.project_id
}

resource "equinix_metal_port_vlan_attachment" "test1" {
  device_id = equinix_metal_device_network_type.test.id
  vlan_vnid = equinix_metal_vlan.test1.vxlan
  port_name = "eth1"
}

resource "equinix_metal_port_vlan_attachment" "test2" {
  device_id  = equinix_metal_device_network_type.test.id
  vlan_vnid  = equinix_metal_vlan.test2.vxlan
  port_name  = "eth1"
  native     = true
  depends_on = ["equinix_metal_port_vlan_attachment.test1"]
}

Référence de l'argument

Les arguments suivants sont soutenus :

• device_id - (Obligatoire) ID de l'appareil à affecter au VLAN.
• port_name - (Obligatoire) Nom du port réseau à affecter au VLAN.
• vlan_vnid - (Obligatoire) Identifiant du réseau VXLAN.
• force_bond - (Facultatif) Ajoutez le port à la liaison lorsque cette ressource est supprimée. La valeur par défaut est false.
• native - (Facultatif) Marquez ce VLAN comme VLAN natif sur le port. Cette option ne peut être utilisée que si cette affectation attribue un deuxième VLAN ou un VLAN supplémentaire au port. Pour garantir que cet attachement n'est pas le premier sur un port, vous pouvez utiliser depends_on pointant vers un autre equinix_metal_port_vlan_attachment, comme dans l'exemple layer2-individual ci-dessus.

Référence d'attribut

En plus de tous les arguments ci-dessus, les attributs suivants sont exportés :

• id - UUID du port de l'appareil utilisé dans l'affectation.
• vlan_id - UUID de la ressource API VLAN.
• port_id - UUID du port de l'appareil.