equinix_fabric_connection (Ressource)

Ressource compatible avec l'API Fabric V4 permettant de créer et de gérer une connexion Equinix Fabric.

Documentation complémentaire :

• Pour commencer : https://docs.equinix.com/api-catalog/fabricv4/
• API : https://docs.equinix.com/api-catalog/fabricv4/#tag/Connections

Modules de soutien

L'utilisation directe des ressources est décrite dans la section suivante "Exemple d'utilisation". Nous avons également des modules Terraform de soutien qui peuvent être utilisés pour vous aider dans les cas d'utilisation courants de Fabric Connection.

Vous pouvez trouver ces modules ainsi que leurs exemples d'utilisation sur le Terraform Registry : (Fabric Terraform Modules).

Exemple d'utilisation

Connexion port à port EVPL_VC :

resource "equinix_fabric_connection" "port2port" {
  name = "ConnectionName"
  type = "EVPL_VC"
  notifications {
    type = "ALL"
    emails = ["example@equinix.com","test1@equinix.com"]
  }
  bandwidth = 50
  order {
    purchase_order_number= "1-323292"
  }
  a_side {
    access_point {
      type = "COLO"
      port {
        uuid = "<aside_port_uuid>"
      }
      link_protocol {
        type = "QINQ"
        vlan_s_tag = "1976"
        
      }
    }
  }
  z_side {
    access_point {
      type = "COLO"
      port {
        uuid = "<zside_port_uuid>"
      }
      link_protocol {
        type = "QINQ"
        vlan_s_tag = "3711"
      }
      location {
        metro_code= "SV"
      }
    }
  }
}

Port vers AWS EVPL_VC Connexion :

resource "equinix_fabric_connection" "port2aws" {
  name = "ConnectionName"
  type = "EVPL_VC"
  notifications {
    type = "ALL"
    emails = ["example@equinix.com","test1@equinix.com"]
  }
  bandwidth = 50
  redundancy { priority= "PRIMARY" }
  order {
    purchase_order_number= "1-323929"
  }
  a_side {
    access_point {
      type= "COLO"
      port {
        uuid = "<aside_port_uuid>"
      }
      link_protocol {
        type = "QINQ"
        vlan_s_tag = "2019"
        vlan_c_tag = "2112"
      }
    }
  }
  z_side {
    access_point {
      type = "SP"
      authentication_key = "<aws_account_id>"
      seller_region = "us-west-1"
      profile {
        type = "L2_PROFILE"
        uuid = "<service_profile_uuid>"
      }
      location {
        metro_code = "SV"
      }
    }
  }
  
  additional_info = [
    { key = "accessKey", value = "<aws_access_key>" },
    { key = "secretKey", value = "<aws_secret_key>" }
  ]
}

Connexion EPL de port à port :

resource "equinix_fabric_connection" "epl" {
  name = "ConnectionName"
  type = "EPL_VC"
  notifications {
    type   = "ALL"
    emails = ["example@equinix.com", "test1@equinix.com"]
  }
  bandwidth = 50
  order {
    purchase_order_number = "1-323292"
  }
  a_side {
    access_point {
      type = "COLO"
      port {
        uuid = "<aside_port_uuid>"
      }
    }
  }
  z_side {
    access_point {
      type = "COLO"
      port {
        uuid = "<zside_port_uuid>"
      }
      location {
        metro_code = "SV"
      }
    }
  }
}

Port à port ACCESS_EPL_VC Connexion :

resource "equinix_fabric_connection" "access_epl_vc" {
  name = "ConnectionName"
  type = "ACCESS_EPL_VC"
  notifications {
    type   = "ALL"
    emails = ["example@equinix.com", "test1@equinix.com"]
  }
  bandwidth = 50
  order {
    purchase_order_number = "1-323292"
  }
  a_side {
    access_point {
      type = "COLO"
      port {
        uuid = "<aside_port_uuid>"
      }
      link_protocol {
        type       = "QINQ"
        vlan_s_tag = "1976"
      }
    }
  }
  z_side {
    access_point {
      type = "COLO"
      port {
        uuid = "<zside_port_uuid>"
      }
      location {
        metro_code = "SV"
      }
    }
  }
}

Connexion d'un dispositif virtuel à un port :

resource "equinix_fabric_connection" "vd2port" {
  name = "ConnectionName"
  type = "EVPL_VC"
  notifications {
    type   = "ALL"
    emails = ["example@equinix.com", "test1@equinix.com"]
  }
  bandwidth = 50
  order {
    purchase_order_number = "1-323292"
  }
  a_side {
    access_point {
      type = "VD"
      virtual_device {
        type = "EDGE"
        uuid = "<device_uuid>"
      }
      interface {
        type = "NETWORK"
        id = 7
      }
    }
  }
  z_side {
    access_point {
      type = "COLO"
      port {
        uuid = "<zside_port_uuid>"
      }
      link_protocol {
        type       = "DOT1Q"
        vlan_s_tag = "3711"
      }
      location {
        metro_code = "SV"
      }
    }
  }
}

Connexion d'un dispositif virtuel à un jeton de service :

resource "equinix_fabric_connection" "vd2token" {
  name = "ConnectionName"
  type = "EVPL_VC"
  notifications {
    type   = "ALL"
    emails = ["example@equinix.com", "test1@equinix.com"]
  }
  bandwidth = 50
  order {
    purchase_order_number = "1-323292"
  }
  a_side {
    access_point {
      type = "VD"
      virtual_device {
        type = "EDGE"
        uuid = "<device_uuid>"
      }
      interface {
        type = "NETWORK"
        id = 7
      }
    }
  }
  z_side {
    service_token {
      uuid = "<service_token_uuid>"
    }
  }
}

Jeton de service pour la connexion AWS :

resource "equinix_fabric_connection" "token2aws" {
  name = "ConnectionName"
  type = "EVPL_VC"
  notifications {
    type   = "ALL"
    emails = ["example@equinix.com", "test1@equinix.com"]
  }
  bandwidth = 50
  order {
    purchase_order_number = "1-323292"
  }
  a_side {
    service_token {
      uuid = "<service_token_uuid>"
    }
  }
  z_side {
    access_point {
      type = "SP"
      authentication_key = "<aws_account_id>"
      seller_region = "us-west-1"
      profile {
        type = "L2_PROFILE"
        uuid = "<service_profile_uuid>"
      }
      location {
        metro_code = "SV"
      }
    }
  }
}

Connexion du routeur cloud au port :

resource "equinix_fabric_connection" "fcr2port"{
  name = "ConnectionName"
  type = "IP_VC"
  notifications{
    type = "ALL"
    emails = ["example@equinix.com","test1@equinix.com"]
  }
  bandwidth = 50
  order {
    purchase_order_number = "1-323292"
  }
  a_side {
    access_point {
      type = "CLOUD_ROUTER"
      router {
        uuid = "<cloud_router_uuid>"
      }
    }
  }
  z_side {
    access_point {
      type = "COLO"
      port {
        uuid = "<port_uuid>"
      }
      link_protocol {
        type = "DOT1Q"
        vlan_tag = "2711"
      }
      location {
        metro_code = "SV"
      }
    }
  }
}

Cloud Router to Azure Connection :

resource "equinix_fabric_connection" "fcr2azure"{
  name = "ConnectionName"
  type = "IP_VC"
  notifications{
    type = "ALL"
    emails = ["example@equinix.com","test1@equinix.com"]
  }
  bandwidth = 50
  order {
    purchase_order_number = "1-323292"
  }
  a_side {
    access_point {
      type = "CLOUD_ROUTER"
      router {
        uuid = "<cloud_router_uuid>"
      }
    }
  }
  z_side {
    access_point {
      type = "SP"
      authentication_key = "<Azure_ExpressRouter_Auth_Key>"
      peering_type = "PRIVATE"
      profile {
        type = "L2_PROFILE"
        uuid = "<Azure_Service_Profile_UUID>"
      }
      location {
        metro_code = "SV"
      }
    }
  }
}

Connexion d'un dispositif virtuel à Azure :

resource "equinix_fabric_connection" "vd2azure" {
  name = "ConnectionName"
  type = "EVPL_VC"
  notifications {
    type   = "ALL"
    emails = ["example@equinix.com", "test1@equinix.com"]
  }
  bandwidth = 50
  order {
    purchase_order_number = "1-323292"
  }
  a_side {
    access_point {
      type = "VD"
      virtual_device {
        type = "EDGE"
        uuid = "<device_uuid>"
      }
      interface {
        type = "CLOUD"
        id = 7
      }
    }
  }
  z_side {
    access_point {
      type = "SP"
      authentication_key = "<Azure_ExpressRouter_Auth_Key>"
      peering_type = "PRIVATE"
      profile {
        type = "L2_PROFILE"
        uuid = "<Azure_Service_Profile_UUID>"
      }
      location {
        metro_code = "SV"
      }
    }
  }
}

Connexion redondante entre un dispositif virtuel et Azure :

resource "equinix_fabric_connection" "vd2azure_primary" {
  name = "ConnectionName"
  type = "EVPL_VC"
  redundancy { priority = "PRIMARY" }
  notifications {
    type   = "ALL"
    emails = ["example@equinix.com", "test1@equinix.com"]
  }
  bandwidth = 50
  order {
    purchase_order_number = "1-323292"
  }
  a_side {
    access_point {
      type = "VD"
      virtual_device {
        type = "EDGE"
        uuid = "<device_uuid>"
      }
      interface {
        type = "CLOUD"
        id = 7
      }
    }
  }
  z_side {
    access_point {
      type = "SP"
      authentication_key = "<Azure_ExpressRouter_Auth_Key>"
      peering_type = "PRIVATE"
      profile {
        type = "L2_PROFILE"
        uuid = "<Azure_Service_Profile_UUID>"
      }
      location {
        metro_code = "SV"
      }
    }
  }
}

resource "equinix_fabric_connection" "vd2azure_secondary" {
  name = "ConnectionName"
  type = "EVPL_VC"
  redundancy {
    priority = "SECONDARY"
    group = one(equinix_fabric_connection.vd2azure_primary.redundancy).group
  }
  notifications {
    type   = "ALL"
    emails = ["example@equinix.com", "test1@equinix.com"]
  }
  bandwidth = 50
  order {
    purchase_order_number = "1-323292"
  }
  a_side {
    access_point {
      type = "VD"
      virtual_device {
        type = "EDGE"
        uuid = "<device_uuid>"
      }
      interface {
        type = "CLOUD"
        id = 5
      }
    }
  }
  z_side {
    access_point {
      type = "SP"
      authentication_key = "<Azure_ExpressRouter_Auth_Key>"
      peering_type = "PRIVATE"
      profile {
        type = "L2_PROFILE"
        uuid = "<Azure_Service_Profile_UUID>"
      }
      location {
        metro_code = "SV"
      }
    }
  }
}

Connexion du routeur cloud au réseau :

resource "equinix_fabric_connection" "fcr2network"{
  name = "ConnectionName"
  type = "IPWAN_VC"
  notifications{
    type = "ALL"
    emails = ["example@equinix.com","test1@equinix.com"]
  }
  bandwidth = 50
  order {
    purchase_order_number = "1-323292"
  }
  a_side {
    access_point {
      type = "CLOUD_ROUTER"
      router {
        uuid = "<cloud_router_uuid>"
      }
    }
  }
  z_side {
    access_point {
      type = "NETWORK"
      network {
        uuid = "<network_uuid>"
      }
    }
  }
}

Connexion d'un dispositif virtuel à un réseau :

resource "equinix_fabric_connection" "vd2network" {
  name = "ConnectionName"
  type = "EVPLAN_VC"
  notifications {
    type   = "ALL"
    emails = ["example@equinix.com", "test1@equinix.com"]
  }
  bandwidth = 50
  order {
    purchase_order_number = "1-323292"
  }
  a_side {
    access_point {
      type = "VD"
      virtual_device {
        type = "EDGE"
        uuid = "<device_uuid>"
      }
      interface {
        type = "CLOUD"
        id = 7
      }
    }
  }
  z_side {
    access_point {
      type = "NETWORK"
      network {
        uuid = "<network_uuid>"
      }
    }
  }
}

Connexion du port EPLAN au réseau :

resource "equinix_fabric_connection" "eplan" {
  name = "ConnectionName"
  type = "EPLAN_VC"
  notifications {
    type   = "ALL"
    emails = ["example@equinix.com", "test1@equinix.com"]
  }
  bandwidth = 50
  order {
    purchase_order_number = "1-323292"
  }
  a_side {
    access_point {
      type = "COLO"
      port {
        uuid = "<aside_port_uuid>"
      }
    }
  }
  z_side {
    access_point {
      type = "NETWORK"
      network {
        uuid = "<network_uuid>"
      }
    }
  }
}

EVPLAN Port to Network Connection :

resource "equinix_fabric_connection" "evplan" {
  name = "ConnectionName"
  type = "EVPLAN_VC"
  notifications {
    type   = "ALL"
    emails = ["example@equinix.com", "test1@equinix.com"]
  }
  bandwidth = 50
  order {
    purchase_order_number = "1-323292"
  }
  a_side {
    access_point {
      type = "COLO"
      port {
        uuid = "<aside_port_uuid>"
      }
      link_protocol {
        type = "DOT1Q"
        vlan_s_tag = "1976"

      }
    }
  }
  z_side {
    access_point {
      type = "NETWORK"
      network {
        uuid = "<network_uuid>"
      }
    }
  }
}

(Intégration Metal-Fabric) Connexion Metal à AWS EVPL_VC :

resource "equinix_fabric_connection" "metal2aws" {
  name = "ConnectionName"
  type = "EVPLAN_VC"
  notifications {
    type   = "ALL"
    emails = ["example@equinix.com", "test1@equinix.com"]
  }
  bandwidth = 50
  order {
    purchase_order_number = "1-323292"
  }
  a_side {
    access_point {
      type               = "METAL_NETWORK"
      authentication_key = "<metal_authorization_code>"
    }
  }
  z_side {
    access_point {
      type = "SP"
      authentication_key = "<aws_account_id>"
      seller_region = "us-west-1"
      profile {
        type = "L2_PROFILE"
        uuid = "<service_profile_uuid>"
      }
      location {
        metro_code = "SV"
      }
    }
  }
}

(Intégration Metal-Fabric) Fabric Cloud Router to Metal IP_VC Connection :

resource "equinix_fabric_connection" "fcr2metal" {
  name = "ConnectionName"
  type = "IP_VC"
  notifications {
    type   = "ALL"
    emails = ["example@equinix.com", "test1@equinix.com"]
  }
  bandwidth = 50
  order {
    purchase_order_number = "1-323292"
  }
  a_side {
    access_point {
      type = "CLOUD_ROUTER"
      router {
        uuid = "<cloud_router_uuid>"
      }
    }
  }
  z_side {
    access_point {
      type               = "METAL_NETWORK"
      authentication_key = "<metal_authorization_code>"
    }
  }
}

Port to Alibaba Connection EVPL_VC Connection :

Instructions étape par étape pour l'exemple de connexion Fabric Port to Fabric Alibaba Profile donné ci-dessous

1. Créez et acceptez la connexion

• Créez la connexion à l'aide du fournisseur Equinix Terraform.
• Acceptez ensuite manuellement la demande de connexion dans le portail Alibaba pour la connexion physique créée.

2. Supprimer les ressources

• Exécutez terraform destroy pour supprimer le VBR Alibaba
• La suppression directe de la connexion Equinix Fabric entraîne l'erreur suivante : ERR-UAA-003-00: Deletion for a provisioned connection needs to be initiated from Alibaba Portal
• Allez sur le portail Alibaba pour manuellement mettre fin à et ensuite supprimer la connexion physique.
• Cette action supprimera automatiquement la connexion du côté d'Equinix, mettant à jour son statut à Deprovisioned (déprovisionné) du côté d'Equinix et du côté du fournisseur.

resource "equinix_fabric_connection" "port2alibaba" {
  name = "ConnectionName"
  type = "EVPL_VC"
  notifications {
    type = "ALL"
    emails = ["example@equinix.com", "test1@equinix.com"]
  }
  bandwidth = 50
  redundancy { priority = "PRIMARY" }
  order {
    purchase_order_number = "1-323929"
  }
  a_side {
    access_point {
      type = "COLO"
      port {
        uuid = "<aside_port_uuid>"
      }
      link_protocol {
        type     = "DOT1Q"
        vlan_tag = "2019"
      }
    }
  }
  z_side {
    access_point {
      type               = "SP"
      authentication_key = "<alibaba_account_id>"
      seller_region      = "us-west-1"
      profile {
        type = "L2_PROFILE"
        uuid = "<service_profile_uuid>"
      }
      location {
        metro_code = "SV"
      }
    }
  }
}

Notes :

Le port vers IBM Connections pourrait être modifié du côté du fournisseur de services IBM en utilisant les paramètres passés dans le champ additional_info :

• {"key": "ASN", "value": "1111"}
• {"key": "Global", "value": "false"}
• {"key": "BGP_IBM_CIDR", "value": "172.16.0.18/30"}
• {"key": "BGP_CER_CIDR", "value": "172.16.0.19/30"}

Pour accepter, supprimer ou mettre à niveau la bande passante pour IBM Connections à l'aide de la ressource 'ibm_dl_gateway_action', vous devez mettre à jour l'attribut suivant : Pour l'approbation de la connexion :

• Utilisez l'action = "create_gateway_approve" Pour la mise à niveau ou la réduction de la bande passante :
• Utilisez action = "update_attributes_approve" Pour la suppression de connexion :
• Use action = "delete_gateway_approve"

Schéma

Exigée

• a_side (Block Set, Min : 1, Max : 1) Objet de configuration de la connexion côté demandeur ou client de la connexion multi-segments (voir ci-dessous pour le schéma imbriqué)
• bandwidth (Nombre) Largeur de bande de la connexion en Mbps
• name (Chaîne) Nom de la connexion. Une chaîne alphanumérique de 24 caractères qui ne peut inclure que des traits d'union et des traits de soulignement.
• notifications (Liste de blocs, Min : 1) Préférences pour les notifications sur la configuration de la connexion ou les changements d'état (voir ci-dessous pour le schéma imbriqué)
• type (Chaîne) Définit le type de connexion comme EVPL_VC, EPL_VC, IPWAN_VC, IP_VC, ACCESS_EPL_VC, EVPLAN_VC, EPLAN_VC, EIA_VC, IA_VC, EC_VC.
• z_side (Block Set, Min : 1, Max : 1) Objet de configuration de la connexion côté destination ou côté fournisseur de la connexion multi-segments (voir ci-dessous pour le schéma imbriqué)

En option

• additional_info (Liste de cartes de chaînes) Informations supplémentaires sur la connexion
• description (Chaîne) Description de la connexion fournie par le client
• order (Block Set, Max : 1) Détails de la commande (voir ci-dessous pour le schéma imbriqué)
• project (Block Set, Max : 1) Informations sur le projet (voir ci-dessous pour le schéma imbriqué)
• redundancy (Block Set, Max : 1) Configuration de la redondance de la connexion (voir ci-dessous pour le schéma imbriqué)
• timeouts (Bloc, Facultatif) (voir ci-dessous pour le schéma imbriqué)

En lecture seule

• account (Set of Object) Customer account information that is associated with this connection (see below for nested schema)
• change_log (Ensemble d'objets) Capture les informations sur les modifications du cycle de vie des connexions (voir ci-dessous pour le schéma imbriqué)
• direction (Chaîne) Directionnalité de la connexion du point de vue du demandeur
• href (Chaîne) Informations sur l'URI de connexion
• id (Chaîne) L'identifiant de cette ressource.
• is_remote (booléen) Propriété de connexion dérivée de l'emplacement des points d'accès
• operation (Ensemble d'objets) Données opérationnelles spécifiques au type de connexion (voir ci-dessous pour le schéma imbriqué)
• state (String) État général de la connexion
• uuid (Chaîne) Identifiant de connexion attribué par Equinix

Schéma imbriqué pour a_side

En option :

• access_point (Block Set, Max : 1) Détails du point d'accès (voir ci-dessous pour le schéma imbriqué)
• additional_info (Block List) Connection side additional information (see below for nested schema)
• service_token (Jeu de blocs, Max : 1) Pour les connexions basées sur des jetons de service, les jetons de service autorisent les utilisateurs à accéder aux ressources et aux services protégés. Les propriétaires de ressources peuvent distribuer les jetons à des partenaires et fournisseurs de confiance, ce qui permet à des tiers sélectionnés de travailler directement avec les ressources du réseau Equinix (voir ci-dessous pour le schéma imbriqué).

Schéma imbriqué pour a_side.access_point

En option :

• authentication_key (String) Clé d'authentification pour les connexions basées sur les fournisseurs ou les connexions d'intégration Metal-Fabric.
• gateway (Jeu de blocs, Max : 1, Obsolète) Obsolète gateway Utilisez l'attribut router à la place (voir ci-dessous pour le schéma imbriqué)
• interface (Block Set, Max : 1) Virtual device interface (see below for nested schema)
• link_protocol (Ensemble de blocs, Max : 1) Protocole de liaison de connexion (voir ci-dessous pour le schéma imbriqué)
• location (Block Set, Max : 1) Emplacement du point d'accès (voir ci-dessous pour le schéma imbriqué)
• network (Block Set, Max : 1) informations sur le point d'accès au réseau (voir ci-dessous pour le schéma imbriqué)
• peering_type (Chaîne) Type de peering- PRIVE,MICROSOFT,PUBLIC, MANUEL
• port (Block Set, Max : 1) Port access point information (see below for nested schema)
• profile (Block Set, Max : 1) Service Profile (see below for nested schema)
• role (Chaîne) Rôle du réseau
• router (Block Set, Max : 1) Informations sur le point d'accès du routeur du nuage qui remplace gateway (voir ci-dessous pour le schéma imbriqué)
• seller_region (Chaîne) Région du vendeur du point d'accès
• type (String) Type de point d'accès - COLO, VD, VG, SP, IGW, SUBNET, CLOUD_ROUTER, NETWORK, METAL_NETWORK
• virtual_device (Block Set, Max : 1) Dispositif virtuel (voir ci-dessous pour le schéma imbriqué)

En lecture seule :

• account (Block Set) Account (see below for nested schema)
• provider_connection_id (Chaîne) Identifiant de connexion attribué par le fournisseur

Schéma imbriqué pour a_side.access_point.gateway

En option :

• uuid (Chaîne) Identifiant de passerelle virtuelle attribué par Equinix

En lecture seule :

• href (Chaîne) Identifiant de ressource unique

Schéma imbriqué pour a_side.access_point.interface

En option :

• id (Nombre) id
• type (Chaîne) Type d'interface
• uuid (Chaîne) Identifiant d'interface attribué par Equinix

Schéma imbriqué pour a_side.access_point.link_protocol

En option :

• type (Chaîne) Type de protocole de liaison - UNTAGGED, DOT1Q, QINQ, EVPN_VXLAN
• vlan_c_tag (Number) Vlan Customer Tag information, vlanCTag value specified for QINQ connections
• vlan_s_tag (Number) Vlan Provider Tag information, vlanSTag value specified for QINQ connections
• vlan_tag (Number) Vlan Tag information, vlanTag value specified for DOT1Q connections

Schéma imbriqué pour a_side.access_point.location

En option :

• ibx (Chaîne) Code IBX
• metro_code (Chaîne) Code métro du point d'accès
• metro_name (String) Nom de métro du point d'accès
• region (Chaîne) Région du point d'accès

Schéma imbriqué pour a_side.access_point.network

Obligatoire :

• uuid (Chaîne) Identifiant de réseau attribué par Equinix

En lecture seule :

• href (Chaîne) Identifiant de ressource unique

Schéma imbriqué pour a_side.access_point.port

En option :

• uuid (Chaîne) Identifiant de port attribué par Equinix

En lecture seule :

• href (Chaîne) Identifiant de ressource unique
• name (Chaîne) Nom du port
• redundancy (Set of Object) Redundancy Information (see below for nested schema)

Schéma imbriqué pour a_side.access_point.port.redundancy

En lecture seule :

• enabled (booléen)
• group (Chaîne)
• priority (Chaîne)

Schéma imbriqué pour a_side.access_point.profile

Obligatoire :

• type (Chaîne) Type de profil de service - L2_PROFILE, L3_PROFILE, ECIA_PROFILE, ECMC_PROFILE, IA_PROFILE
• uuid (Chaîne) Identifiant de profil de service attribué par Equinix

En lecture seule :

• access_point_type_configs (Liste d'objets) Informations de configuration du point d'accès (voir ci-dessous pour le schéma imbriqué)
• description (Chaîne) Description du service fournie par l'utilisateur
• href (Chaîne) Attribut de réponse de l'URI du profil de service
• name (Chaîne) Nom du profil de service attribué par le client

Schéma imbriqué pour a_side.access_point.profile.access_point_type_configs

En lecture seule :

• type (Chaîne)
• uuid (Chaîne)

Schéma imbriqué pour a_side.access_point.router

En option :

• uuid (Chaîne) Identifiant de passerelle virtuelle attribué par Equinix

En lecture seule :

• href (Chaîne) Identifiant de ressource unique

Schéma imbriqué pour a_side.access_point.virtual_device

Obligatoire :

• uuid (Chaîne) Identifiant du dispositif virtuel attribué par Equinix

En option :

• name (Chaîne) Nom de l'appareil virtuel attribué par le client
• type (Chaîne) Type de dispositif virtuel

En lecture seule :

• href (Chaîne) Identifiant de ressource unique

Schéma imbriqué pour a_side.access_point.account

En lecture seule :

• account_name (Chaîne) Nom légal du titulaire du compte.
• account_number (Numéro) Numéro de compte attribué par Equinix.
• global_cust_id (Chaîne) ID attribué par Equinix à l'organisation mère de l'abonné.
• global_org_id (Chaîne) ID attribué par Equinix à l'organisation mère de l'abonné.
• global_organization_name (Chaîne) Nom attribué par Equinix à l'organisation mère de l'abonné.
• org_id (Numéro) ID attribué par Equinix à l'organisation de l'abonné.
• organization_name (Chaîne) Nom de l'organisation de l'abonné attribué par Equinix.
• ucm_id (Chaîne) Identifiant du magasin de données de l'entreprise

Schéma imbriqué pour a_side.additional_info

En option :

• key (Chaîne) Clé d'information supplémentaire
• value (Chaîne) Valeur d'information supplémentaire

Schéma imbriqué pour a_side.service_token

En option :

• type (Chaîne) Type de jeton - VC_TOKEN
• uuid (Chaîne) Identifiant du jeton de service attribué par Equinix

En lecture seule :

• description (Chaîne) Description du jeton de service
• href (Chaîne) URL absolue faisant l'objet du contexte du lien

Schéma imbriqué pour notifications

Obligatoire :

• emails (List of String) Tableau de courriels de contact
• type (Chaîne) Type de notification - ALL,CONNECTION_APPROVAL,SALES_REP_NOTIFICATIONS, NOTIFICATIONS

En option :

• send_interval (Chaîne) Intervalle d'envoi

Schéma imbriqué pour z_side

En option :

• access_point (Block Set, Max : 1) Détails du point d'accès (voir ci-dessous pour le schéma imbriqué)
• additional_info (Block List) Connection side additional information (see below for nested schema)
• service_token (Jeu de blocs, Max : 1) Pour les connexions basées sur des jetons de service, les jetons de service autorisent les utilisateurs à accéder aux ressources et aux services protégés. Les propriétaires de ressources peuvent distribuer les jetons à des partenaires et fournisseurs de confiance, ce qui permet à des tiers sélectionnés de travailler directement avec les ressources du réseau Equinix (voir ci-dessous pour le schéma imbriqué).

Schéma imbriqué pour z_side.access_point

En option :

• authentication_key (String) Clé d'authentification pour les connexions basées sur les fournisseurs ou les connexions d'intégration Metal-Fabric.
• gateway (Jeu de blocs, Max : 1, Obsolète) Obsolète gateway Utilisez l'attribut router à la place (voir ci-dessous pour le schéma imbriqué)
• interface (Block Set, Max : 1) Virtual device interface (see below for nested schema)
• link_protocol (Ensemble de blocs, Max : 1) Protocole de liaison de connexion (voir ci-dessous pour le schéma imbriqué)
• location (Block Set, Max : 1) Emplacement du point d'accès (voir ci-dessous pour le schéma imbriqué)
• network (Block Set, Max : 1) informations sur le point d'accès au réseau (voir ci-dessous pour le schéma imbriqué)
• peering_type (Chaîne) Type de peering- PRIVE,MICROSOFT,PUBLIC, MANUEL
• port (Block Set, Max : 1) Port access point information (see below for nested schema)
• profile (Block Set, Max : 1) Service Profile (see below for nested schema)
• role (Chaîne) Rôle du réseau
• router (Block Set, Max : 1) Informations sur le point d'accès du routeur du nuage qui remplace gateway (voir ci-dessous pour le schéma imbriqué)
• seller_region (Chaîne) Région du vendeur du point d'accès
• type (String) Type de point d'accès - COLO, VD, VG, SP, IGW, SUBNET, CLOUD_ROUTER, NETWORK, METAL_NETWORK
• virtual_device (Block Set, Max : 1) Dispositif virtuel (voir ci-dessous pour le schéma imbriqué)

En lecture seule :

• account (Block Set) Account (see below for nested schema)
• provider_connection_id (Chaîne) Identifiant de connexion attribué par le fournisseur

Schéma imbriqué pour z_side.access_point.gateway

En option :

• uuid (Chaîne) Identifiant de passerelle virtuelle attribué par Equinix

En lecture seule :

• href (Chaîne) Identifiant de ressource unique

Schéma imbriqué pour z_side.access_point.interface

En option :

• id (Nombre) id
• type (Chaîne) Type d'interface
• uuid (Chaîne) Identifiant d'interface attribué par Equinix

Schéma imbriqué pour z_side.access_point.link_protocol

En option :

• type (Chaîne) Type de protocole de liaison - UNTAGGED, DOT1Q, QINQ, EVPN_VXLAN
• vlan_c_tag (Number) Vlan Customer Tag information, vlanCTag value specified for QINQ connections
• vlan_s_tag (Number) Vlan Provider Tag information, vlanSTag value specified for QINQ connections
• vlan_tag (Number) Vlan Tag information, vlanTag value specified for DOT1Q connections

Schéma imbriqué pour z_side.access_point.location

En option :

• ibx (Chaîne) Code IBX
• metro_code (Chaîne) Code métro du point d'accès
• metro_name (String) Nom de métro du point d'accès
• region (Chaîne) Région du point d'accès

Schéma imbriqué pour z_side.access_point.network

Obligatoire :

• uuid (Chaîne) Identifiant de réseau attribué par Equinix

En lecture seule :

• href (Chaîne) Identifiant de ressource unique

Schéma imbriqué pour z_side.access_point.port

En option :

• uuid (Chaîne) Identifiant de port attribué par Equinix

En lecture seule :

• href (Chaîne) Identifiant de ressource unique
• name (Chaîne) Nom du port
• redundancy (Set of Object) Redundancy Information (see below for nested schema)

Schéma imbriqué pour z_side.access_point.port.redundancy

En lecture seule :

• enabled (booléen)
• group (Chaîne)
• priority (Chaîne)

Schéma imbriqué pour z_side.access_point.profile

Obligatoire :

• type (Chaîne) Type de profil de service - L2_PROFILE, L3_PROFILE, ECIA_PROFILE, ECMC_PROFILE, IA_PROFILE
• uuid (Chaîne) Identifiant de profil de service attribué par Equinix

En lecture seule :

• access_point_type_configs (Liste d'objets) Informations de configuration du point d'accès (voir ci-dessous pour le schéma imbriqué)
• description (Chaîne) Description du service fournie par l'utilisateur
• href (Chaîne) Attribut de réponse de l'URI du profil de service
• name (Chaîne) Nom du profil de service attribué par le client

Schéma imbriqué pour z_side.access_point.profile.access_point_type_configs

En lecture seule :

• type (Chaîne)
• uuid (Chaîne)

Schéma imbriqué pour z_side.access_point.router

En option :

• uuid (Chaîne) Identifiant de passerelle virtuelle attribué par Equinix

En lecture seule :

• href (Chaîne) Identifiant de ressource unique

Schéma imbriqué pour z_side.access_point.virtual_device

Obligatoire :

• uuid (Chaîne) Identifiant du dispositif virtuel attribué par Equinix

En option :

• name (Chaîne) Nom de l'appareil virtuel attribué par le client
• type (Chaîne) Type de dispositif virtuel

En lecture seule :

• href (Chaîne) Identifiant de ressource unique

Schéma imbriqué pour z_side.access_point.account

En lecture seule :

• account_name (Chaîne) Nom légal du titulaire du compte.
• account_number (Numéro) Numéro de compte attribué par Equinix.
• global_cust_id (Chaîne) ID attribué par Equinix à l'organisation mère de l'abonné.
• global_org_id (Chaîne) ID attribué par Equinix à l'organisation mère de l'abonné.
• global_organization_name (Chaîne) Nom attribué par Equinix à l'organisation mère de l'abonné.
• org_id (Numéro) ID attribué par Equinix à l'organisation de l'abonné.
• organization_name (Chaîne) Nom de l'organisation de l'abonné attribué par Equinix.
• ucm_id (Chaîne) Identifiant du magasin de données de l'entreprise

Schéma imbriqué pour z_side.additional_info

En option :

• key (Chaîne) Clé d'information supplémentaire
• value (Chaîne) Valeur d'information supplémentaire

Schéma imbriqué pour z_side.service_token

En option :

• type (Chaîne) Type de jeton - VC_TOKEN
• uuid (Chaîne) Identifiant du jeton de service attribué par Equinix

En lecture seule :

• description (Chaîne) Description du jeton de service
• href (Chaîne) URL absolue faisant l'objet du contexte du lien

Schéma imbriqué pour order

En option :

• billing_tier (String) Niveau de facturation de la bande passante de connexion
• order_id (Chaîne) Identification de la commande
• order_number (Chaîne) Numéro de référence de la commande
• purchase_order_number (Chaîne) Numéro de commande
• term_length (Nombre) Durée de la période en mois ; les valeurs valides sont 1, 12, 24, 36 où 1 est la valeur par défaut (pour le cas à la demande).

Schéma imbriqué pour project

En option :

• project_id (Chaîne) Id du projet

En lecture seule :

• href (Chaîne) URL de ressource unique

Schéma imbriqué pour redundancy

En option :

• group (Chaîne) Identifiant du groupe de redondance (Utilisez l'UUID redundancy.0.group de la connexion primaire ; par exemple one(equinix_fabric_connection.primary_port_connection.redundancy).group ou equinix_fabric_connection.primary_port_connection.redundancy.0.group)
• priority (Chaîne) Priorité de connexion dans le groupe de redondance - PRIMARY, SECONDARY

Schéma imbriqué pour timeouts

En option :

• create (Chaîne)
• delete (Chaîne)
• read (Chaîne)
• update (Chaîne)

Schéma imbriqué pour account

En lecture seule :

• account_name (Chaîne)
• account_number (Nombre)
• global_cust_id (Chaîne)
• global_org_id (Chaîne)
• global_organization_name (Chaîne)
• org_id (Nombre)
• organization_name (Chaîne)
• ucm_id (Chaîne)

Schéma imbriqué pour change_log

En lecture seule :

• created_by (Chaîne)
• created_by_email (Chaîne)
• created_by_full_name (Chaîne)
• created_date_time (Chaîne)
• deleted_by (Chaîne)
• deleted_by_email (Chaîne)
• deleted_by_full_name (Chaîne)
• deleted_date_time (Chaîne)
• updated_by (Chaîne)
• updated_by_email (Chaîne)
• updated_by_full_name (Chaîne)
• updated_date_time (Chaîne)

Schéma imbriqué pour operation

En lecture seule :

• equinix_status (Chaîne)
• errors (Liste d'objets) (voir ci-dessous pour le schéma imbriqué)
• provider_status (Chaîne)

Schéma imbriqué pour operation.errors

En lecture seule :

• additional_info (Liste d'objets) (voir ci-dessous pour le schéma imbriqué)
• correlation_id (Chaîne)
• details (Chaîne)
• error_code (Chaîne)
• error_message (Chaîne)
• help (Chaîne)

Schéma imbriqué pour operation.errors.additional_info

En lecture seule :

• property (Chaîne)
• reason (Chaîne)