Avis de fin de vie Equinix Metal ne sera plus pris en charge le 30 juin 2026 Toutes les ressources Metal seront supprimées dans la version 5.0.0 de ce fournisseur. Pour continuer à utiliser ce service jusqu'à cette date, veuillez utiliser la version 4.x. Consultez la page https://docs.equinix.com/metal/ pour plus d'informations.

equinix_metal_vrf (Ressource)

Utilisez cette ressource pour gérer un VRF.

Consultez la [documentation sur le routage et le transfert virtuels pour obtenir des détails sur le produit et des informations de référence sur l'API.

Exemple d'utilisation

Créez un VRF dans la zone métropolitaine désirée et projetez-le avec les plages d'adresses IP que vous voulez que le VRF achemine et transfère.

resource "equinix_metal_project" "example" {
    name = "example"
}

resource "equinix_metal_vrf" "example" {
    description = "VRF with ASN 65000 and a pool of address space that includes 192.168.100.0/25"
    name        = "example-vrf"
    metro       = "da"
    local_asn   = "65000"
    ip_ranges   = ["192.168.100.0/25", "192.168.200.0/25"]
    project_id  = equinix_metal_project.example.id
}

Créez des réservations d'adresses IP et attribuez-les à une ressource de passerelle Metal Gateway. La passerelle se verra attribuer la première adresse du bloc.

resource "equinix_metal_reserved_ip_block" "example" {
    description = "Reserved IP block (192.168.100.0/29) taken from on of the ranges in the VRF's pool of address space."
    project_id  = equinix_metal_project.example.id
    metro       = equinix_metal_vrf.example.metro
    type        = "vrf"
    vrf_id      = equinix_metal_vrf.example.id
    cidr        = 29
    network     = "192.168.100.0"
}

resource "equinix_metal_vlan" "example" {
    description = "A VLAN for Layer2 and Hybrid Metal devices"
    metro       = equinix_metal_vrf.example.metro
    project_id  = equinix_metal_project.example.id
}

resource "equinix_metal_gateway" "example" {
    project_id        = equinix_metal_project.example.id
    vlan_id           = equinix_metal_vlan.example.id
    ip_reservation_id = equinix_metal_reserved_ip_block.example.id
}

Connectez un circuit virtuel à partir d'une connexion métallique dédiée à la passerelle métallique.

data "equinix_metal_connection" "example" {
    connection_id = var.metal_dedicated_connection_id
}

resource "equinix_metal_virtual_circuit" "example" {
    name          = "example-vc"
    description   = "Virtual Circuit"
    connection_id = data.equinix_metal_connection.example.id
    project_id    = equinix_metal_project.example.id
    port_id       = data.equinix_metal_connection.example.ports[0].id
    nni_vlan      = 1024
    vrf_id        = equinix_metal_vrf.example.id
    peer_asn      = 65530
    subnet        = "192.168.100.16/31"
    metal_ip      = "192.168.100.16"
    customer_ip   = "192.168.100.17"
}

Diagramme

Requis

• metro (Chaîne de caractères) ID ou code de la région métropolitaine où le VRF sera déployé
• name (Chaîne de caractères) Nom du VRF fourni par l'utilisateur, unique au projet
• project_id (Chaîne de caractères) ID du projet où le VRF sera déployé

En option

• description (Chaîne de caractères) Description du VRF
• ip_ranges (Ensemble de chaînes de caractères) Toutes les plages d'adresses IPv4 et IPv6 disponibles pour les pairs BGP. Les adresses IPv4 doivent être de type /8 ou plus petite, avec une taille minimale de /29. Les adresses IPv6 doivent être de type /56 ou plus petite, avec une taille minimale de /64. Les plages ne doivent pas se chevaucher au sein du VRF.
• local_asn (Nombre) L'ASN de 4 octets défini sur le VRF.

Lecture seule

• id (Chaîne de caractères) L'identifiant de cette ressource.

Importation

Cette ressource peut être importée à l'aide d'un ID VRF existant:

terraform import equinix_metal_vrf {existing_id}