Avis de fin de vie Equinix Metal ne sera plus pris en charge le 30 juin 2026 Toutes les ressources Metal seront supprimées dans la version 5.0.0 de ce fournisseur. Pour continuer à utiliser ce service jusqu'à cette date, veuillez utiliser la version 4.x. Consultez la page https://docs.equinix.com/metal/ pour plus d'informations.

equinix_metal_port_vlan_attachment (Ressource)

Fournit une ressource permettant d'associer les ports de périphériques aux VLAN.

L'appareil et le VLAN doivent se trouver dans la même région métropolitaine.

Si vous avez besoin que cette ressource ajoute le port à la liaison lors de sa suppression, définissez force_bond = true.

Pour en savoir plus sur le réseautage de couche 2 dans Equinix Metal, consultez la documentation.

• https://docs.equinix.com/metal/layer2-networking/overview/

Exemple d'utilisation

type de réseau hybride

resource "equinix_metal_vlan" "test" {
  description = "VLAN in New York"
  metro       = "ny"
  project_id  = local.project_id
}

resource "equinix_metal_device" "test" {
  hostname         = "test"
  plan             = "c3.small.x86"
  metro            = "ny"
  operating_system = "ubuntu_24_04"
  billing_cycle    = "hourly"
  project_id       = local.project_id
}

resource "equinix_metal_device_network_type" "test" {
  device_id = equinix_metal_device.test.id
  type      = "hybrid"
}

resource "equinix_metal_port_vlan_attachment" "test" {
  device_id = equinix_metal_device_network_type.test.id
  port_name = "eth1"
  vlan_vnid = equinix_metal_vlan.test.vxlan
}

Réseau de couche 2

resource "equinix_metal_device" "test" {
  hostname         = "test"
  plan             = "c3.small.x86"
  metro            = "ny"
  operating_system = "ubuntu_24_04"
  billing_cycle    = "hourly"
  project_id       = local.project_id
}

resource "equinix_metal_device_network_type" "test" {
  device_id = equinix_metal_device.test.id
  type      = "layer2-individual"
}

resource "equinix_metal_vlan" "test1" {
  description = "VLAN in New York"
  metro       = "ny"
  project_id  = local.project_id
}

resource "equinix_metal_vlan" "test2" {
  description = "VLAN in New Jersey"
  metro       = "ny"
  project_id  = local.project_id
}

resource "equinix_metal_port_vlan_attachment" "test1" {
  device_id = equinix_metal_device_network_type.test.id
  vlan_vnid = equinix_metal_vlan.test1.vxlan
  port_name = "eth1"
}

resource "equinix_metal_port_vlan_attachment" "test2" {
  device_id  = equinix_metal_device_network_type.test.id
  vlan_vnid  = equinix_metal_vlan.test2.vxlan
  port_name  = "eth1"
  native     = true
  depends_on = ["equinix_metal_port_vlan_attachment.test1"]
}

Référence de l'argument

Les arguments suivants sont étayés:

• device_id - (Obligatoire) ID de l'appareil à affecter au VLAN.
• port_name - (Obligatoire) Nom du port réseau à affecter au VLAN.
• vlan_vnid - (Obligatoire) Identifiant du réseau VXLAN.
• force_bond - (Facultatif) Réintègre le port à l'agrégation lorsque cette ressource est supprimée. La valeur par défaut est false.
• native - (Optionnel) Indiquez que ce VLAN est un VLAN natif sur le port. Cette option ne peut être utilisée que si cette affectation attribue un deuxième VLAN ou plus au port. Pour éviter que cet rattachement ne soit le premier sur un port, vous pouvez utiliser depends_on pointant vers un autre equinix_metal_port_vlan_attachment, comme dans l'exemple de couche 2 individuelle ci-dessus.

Référence d'attribut

En plus des arguments ci-dessus, les attributs suivants sont exportés:

• id - UUID du port de l'appareil utilisé dans l'affectation.
• vlan_id - UUID de la ressource API VLAN.
• port_id - UUID du port du périphérique.