Skip to main content

Avis de fin de vie Equinix Metal ne sera plus pris en charge le 30 juin 2026 Toutes les ressources Metal seront supprimées dans la version 5.0.0 de ce fournisseur. Pour continuer à utiliser ce service jusqu'à cette date, veuillez utiliser la version 4.x. Consultez la page https://docs.equinix.com/metal/ pour plus d'informations.

connexion métallique Equinix (Ressource)

Utilisez cette ressource pour demander la création d'un actif d'interconnexion pour vous connecter à d'autres parties en utilisant [Equinix Fabric - interconnexions définies par logiciel.

Exemple d'utilisation​

Connexion virtuelle partagée facturée Fabric - Connexion non redondante entre votre port Fabric Equinix et le serveur Equinix Metal.​

resource "equinix_metal_vlan" "example" {
  project_id = "<metal_project_id>"
  metro      = "FR"
}

resource "equinix_metal_connection" "example" {
  name               = "tf-metal-from-port"
  project_id         = "<metal_project_id>"
  type               = "shared"
  redundancy         = "primary"
  metro              = "FR"
  speed              = "200Mbps"
  service_token_type = "z_side"
  contact_email      = "username@example.com"
  vlans              = [equinix_metal_vlan.example.vxlan]
}

data "equinix_fabric_ports" "a_side" {
  filters {
    name = "<name_of_port||port_prefix>"
  }
}

resource "equinix_fabric_connection" "example" {
  name      = "tf-metal-from-port"
  type      = "EVPL_VC"
  bandwidth = "200"
  notifications {
    type   = "ALL"
    emails = ["username@example.com"]
  }
  order { purchase_order_number = "1-323292" }
  project { project_id = "<fabric_project_id>" }
  a_side {
    access_point {
      type = "COLO"
      port {
        uuid = data.equinix_fabric_ports.a_side.data.0.uuid
      }
      link_protocol {
        type     = "DOT1Q"
        vlan_tag = 1234
      }
    }
  }
  z_side {
    service_token {
      uuid = equinix_metal_connection.example.service_tokens.0.id
    }
  }
}

-> REMARQUE: Un module Terraform [Connexion Equinix Fabric L2 à Equinix Metal est disponible avec des exemples complets de connexions à partir de ports Fabric, de périphériques réseau Edge ou de jetons de service. Consultez l’[exemple de connexion partagée avec un jeton de service côté Z.

Connexion virtuelle partagée facturée Fabric - Connexion non redondante entre votre appareil Network Edge et Equinix Metal.​

resource "equinix_metal_vrf" "example" {
  name       = "tf-metal-from-ne"
  metro      = "FR"
  local_asn  = "65001"
  ip_ranges  = ["10.99.1.0/24"]
  project_id = equinix_metal_project.test.id
}

resource "equinix_metal_connection" "example" {
  name               = "tf-metal-from-ne"
  project_id         = "<metal_project_id>"
  type               = "shared"
  redundancy         = "primary"
  metro              = "FR"
  speed              = "200Mbps"
  service_token_type = "z_side"
  contact_email      = "username@example.com"
  vrfs               = [equinix_metal_vrf.example.vxlan]
}

resource "equinix_fabric_connection" "example" {
  name      = "tf-metal-from-ne"
  type      = "EVPL_VC"
  bandwidth = "200"
  notifications {
    type   = "ALL"
    emails = ["username@example.com"]
  }
  order { purchase_order_number = "1-323292" }
  project { project_id = "<fabric_project_id>" }
  a_side {
    access_point {
      type = "VD"
      virtual_device {
        type = "EDGE"
        uuid = equinix_network_device.example.id
      }
    }
  }
  z_side {
    service_token {
      uuid = equinix_metal_connection.example.service_tokens.0.id
    }
  }
}

Connexion virtuelle partagée facturée Fabric - Connexion non redondante entre le routeur infonuagique Equinix Fabric et le serveur Equinix Metal.​

resource "equinix_metal_vlan" "example1" {
  project_id = "<metal_project_id>"
  metro      = "SV"
}

resource "equinix_metal_connection" "example" {
  name          = "tf-metal-from-fcr"
  project_id    = "<metal_project_id>"
  metro         = "SV"
  redundancy    = "primary"
  type          = "shared_port_vlan"
  contact_email = "username@example.com"
  speed         = "200Mbps"
  vlans         = [equinix_metal_vlan.example1.vxlan]
}

resource "equinix_fabric_connection" "example" {
  name      = "tf-metal-from-fcr"
  type      = "IP_VC"
  bandwidth = "200"
  notifications {
    type   = "ALL"
    emails = ["username@example.com"]
  }
  project { project_id = "<fabric_project_id>" }
  a_side {
    access_point {
      type = "CLOUD_ROUTER"
      router {
        uuid = equinix_fabric_cloud_router.example.id
      }
    }
  }
  z_side {
    access_point {
      type               = "METAL_NETWORK"
      authentication_key = equinix_metal_connection.example.authorization_code
    }
  }
}

Connexion virtuelle partagée facturée Metal - Connexion redondante entre Equinix Metal et un fournisseur de services infonuagiques​

resource "equinix_metal_connection" "example" {
  name               = "tf-metal-2-azure"
  project_id         = "<metal_project_id>"
  type               = "shared"
  redundancy         = "redundant"
  metro              = "SV"
  speed              = "1Gbps"
  service_token_type = "a_side"
  contact_email      = "username@example.com"
}

data "equinix_fabric_service_profiles" "zside" {
  filter {
    property = "/name"
    operator = "="
    values   = ["Azure ExpressRoute"]
  }
}

resource "equinix_fabric_connection" "example_primary" {
  name      = "tf-metal-2-azure-pri"
  type      = "EVPL_VC"
  bandwidth = azurerm_express_route_circuit.example.bandwidth_in_mbps
  redundancy { priority = "PRIMARY" }
  notifications {
    type   = "ALL"
    emails = ["username@example.com"]
  }
  project { project_id = "<fabric_project_id>" }
  a_side {
    service_token {
      uuid = equinix_metal_connection.example.service_tokens.0.id
    }
  }
  z_side {
    access_point {
      type               = "SP"
      authentication_key = azurerm_express_route_circuit.example.service_key
      profile {
        type = "L2_PROFILE"
        uuid = data.equinix_fabric_service_profiles.zside.id
      }
      location {
        metro_code = "SV"
      }
    }
  }
}

resource "equinix_fabric_connection" "example_secondary" {
  name      = "tf-metal-2-azure-sec"
  type      = "EVPL_VC"
  bandwidth = azurerm_express_route_circuit.example.bandwidth_in_mbps
  redundancy {
    priority = "SECONDARY"
    group    = one(equinix_fabric_connection.example_primary.redundancy).group
  }
  notifications {
    type   = "ALL"
    emails = ["username@example.com"]
  }
  project { project_id = "<fabric_project_id>" }
  a_side {
    service_token {
      uuid = equinix_metal_connection.example.service_tokens.1.id
    }
  }
  z_side {
    access_point {
      type               = "SP"
      authentication_key = azurerm_express_route_circuit.example.service_key
      profile {
        type = "L2_PROFILE"
        uuid = data.equinix_fabric_service_profiles.zside.id
      }
      location {
        metro_code = "SV"
      }
    }
  }
}

-> REMARQUE: Plusieurs modules Terraform de connexion Equinix Fabric L2 sont disponibles avec des exemples complets de connexions depuis les ports Fabric, les périphériques réseau Edge ou les jetons de service vers la plupart des fournisseurs de services infonuagiques populaires. Consultez les exemples de connexion partagée Equinix Metal avec jeton de service côté A inclus dans chacun d'eux: AWS, Azure, Google Cloud, IBM Cloud, Oracle Cloud et Alibaba Cloud.

Connexion virtuelle partagée facturée Metal - Connexion non redondante entre Equinix Metal et votre propre port Equinix Fabric​

resource "equinix_metal_connection" "example" {
  name               = "tf-metal-2-port"
  project_id         = "<metal_project_id>"
  type               = "shared"
  redundancy         = "redundant"
  metro              = "FR"
  speed              = "1Gbps"
  service_token_type = "a_side"
  contact_email      = "username@example.com"
}

data "equinix_fabric_ports" "a_side" {
  filters {
    name = "<name_of_port||port_prefix>"
  }
}

resource "equinix_fabric_connection" "example" {
  name = "tf-metal-2-port"
  type = "EVPL_VC"
  notifications {
    type   = "ALL"
    emails = ["username@example.com"]
  }
  project {
    project_id = "<fabric_project_id>"
  }
  bandwidth = "100"
  order {
    purchase_order_number = "1-323292"
  }
  a_side {
    service_token {
      uuid = equinix_metal_connection.example.service_tokens.0.id
    }
  }
  z_side {
    access_point {
      type = "COLO"
      port {
        uuid = data.equinix_fabric_ports.a_side.data.0.uuid
      }
      link_protocol {
        type     = "DOT1Q"
        vlan_tag = 1234
      }
    }
  }
}

Diagramme​

Requis​

  • name (Chaîne) Nom de la ressource de connexion
  • redundancy (Chaîne) Redondance de connexion - redondante ou principale
  • type (Chaîne) Type de connexion: dédiée, partagée ou VLAN à port partagé

En option​

  • contact_email (Chaîne de caractères) L'adresse courriel privilégiée pour les communications et les notifications concernant l'interconnexion Equinix Fabric
  • description (Chaîne de caractères) Description de la ressource de connexion
  • facility (Chaîne de caractères, Déprécié) Installation dans laquelle la connexion sera créée
  • metro (Chaîne de caractères) Métro où la connexion sera créée
  • mode (Chaîne de caractères) Mode de connexion dans les installations IBX avec le type dédié - standard ou tunnel
  • organization_id (Chaîne de caractères) Identifiant de l'organisation responsable de la connexion. Applicable avec le type « dédié ».
  • project_id (Chaîne de caractères) ID du projet auquel la connexion est associée. Obligatoire pour le type « partagé ».
  • service_token_type (Chaîne de caractères) Utilisé uniquement avec une connexion partagée. Type de jeton de service à utiliser pour la connexion: a_side ou z_side.
  • speed (Chaîne de caractères) Vitesse de connexion - Les valeurs doivent être au format ' Mbps ou « « Gbps », par exemple « 100 Mbps » ou « 50 Gbps ». Les valeurs réellement prises en charge dépendent du type de connexion et de l’utilisation de VLAN ou de VRF.
  • tags (Liste de chaînes de caractères) Étiquettes associées à la connexion
  • vlans (Liste de nombres) Utilisé seulement avec une connexion partagée. VLAN à connecter. Indiquez un VLAN pour une connexion principale/unique et deux VLAN pour une connexion redondante.
  • vrfs (Liste de chaînes de caractères) Utilisé uniquement avec une connexion partagée. VRF à connecter. Indiquez un VRF pour une connexion principale/unique et deux VRF pour une connexion redondante.

Lecture seule​

  • authorization_code (Chaîne de caractères) Utilisé uniquement avec une connexion Fabric partagée. Fabric utilise ce jeton pour fournir des informations plus détaillées sur l'extrémité Metal du réseau lors de la consultation des ressources depuis Fabric.
  • id (Chaîne de caractères) L'identificateur unique de la ressource
  • ports (Liste d'objets) Liste des ports de connexion - principal (ports[0]) et secondaire (ports[1]) (voir ci-dessous pour le schéma imbriqué)
  • service_tokens (Liste d'objets) Utilisé seulement avec une connexion partagée. Liste des jetons de service requis pour poursuivre le processus de configuration avec equinix_fabric_connection ou depuis le [portail Equinix Fabric (voir ci-dessous pour le schéma imbriqué)
  • status (Chaîne) État de la ressource de connexion
  • token (Chaîne de caractères, obsolète) Utilisé uniquement avec une connexion partagée. Un jeton Fabric est requis pour poursuivre la configuration via equinix_fabric_connection ou depuis le [portail Equinix Fabric.

Schéma imbriqué pour ports​

Lecture seule:

  • id (Chaîne de caractères)
  • link_status (Chaîne de caractères)
  • name (Chaîne de caractères)
  • role (Chaîne de caractères)
  • speed (Nombre)
  • status (Chaîne de caractères)
  • virtual_circuit_ids (Liste de chaînes de caractères)

Schéma imbriqué pour service_tokens​

Lecture seule:

  • expires_at (Chaîne de caractères)
  • id (Chaîne de caractères)
  • max_allowed_speed (Chaîne de caractères)
  • role (Chaîne de caractères)
  • state (Chaîne de caractères)
  • type (Chaîne de caractères)
Cette page vous a-t-elle été utile ?