~> Deprecation Notice Equinix Metal llegará al final de su vida útil en 30 de junio de 2026. Todos los recursos Metal se eliminarán en la versión 5.0.0 de este proveedor. Utilice la versión 4.x de este proveedor para seguir utilizándolo hasta el final de su vida útil. Consulte https://docs.equinix.com/metal/ para obtener más información.

equinix_metal_vrf (Recurso)

Utilice este recurso para gestionar un VRF.

Consulte la [Documentación sobre enrutamiento y reenvío virtuales para conocer los detalles del producto y el material de referencia de la API.

Ejemplo de uso

Cree un VRF en su metro y proyecto deseado con cualquier rango IP que desee que el VRF enrute y reenvíe.

resource "equinix_metal_project" "example" {
    name = "example"
}

resource "equinix_metal_vrf" "example" {
    description = "VRF with ASN 65000 and a pool of address space that includes 192.168.100.0/25"
    name        = "example-vrf"
    metro       = "da"
    local_asn   = "65000"
    ip_ranges   = ["192.168.100.0/25", "192.168.200.0/25"]
    project_id  = equinix_metal_project.example.id
}

Cree reservas IP y asígnelas a un recurso Metal Gateway. Al Gateway se le asignará la primera dirección del bloque.

resource "equinix_metal_reserved_ip_block" "example" {
    description = "Reserved IP block (192.168.100.0/29) taken from on of the ranges in the VRF's pool of address space."
    project_id  = equinix_metal_project.example.id
    metro       = equinix_metal_vrf.example.metro
    type        = "vrf"
    vrf_id      = equinix_metal_vrf.example.id
    cidr        = 29
    network     = "192.168.100.0"
}

resource "equinix_metal_vlan" "example" {
    description = "A VLAN for Layer2 and Hybrid Metal devices"
    metro       = equinix_metal_vrf.example.metro
    project_id  = equinix_metal_project.example.id
}

resource "equinix_metal_gateway" "example" {
    project_id        = equinix_metal_project.example.id
    vlan_id           = equinix_metal_vlan.example.id
    ip_reservation_id = equinix_metal_reserved_ip_block.example.id
}

Adjunte un circuito virtual de una conexión dedicada de Metal a la puerta de enlace de Metal.

data "equinix_metal_connection" "example" {
    connection_id = var.metal_dedicated_connection_id
}

resource "equinix_metal_virtual_circuit" "example" {
    name          = "example-vc"
    description   = "Virtual Circuit"
    connection_id = data.equinix_metal_connection.example.id
    project_id    = equinix_metal_project.example.id
    port_id       = data.equinix_metal_connection.example.ports[0].id
    nni_vlan      = 1024
    vrf_id        = equinix_metal_vrf.example.id
    peer_asn      = 65530
    subnet        = "192.168.100.16/31"
    metal_ip      = "192.168.100.16"
    customer_ip   = "192.168.100.17"
}

Esquema

Requerido

• metro (Cadena) ID o código de metro donde se desplegará el VRF
• name (Cadena) Nombre suministrado por el usuario del VRF, único para el proyecto
• project_id (Cadena) ID del proyecto donde se desplegará el VRF

Opcional:

• description (Cadena) Descripción del VRF
• ip_ranges (Conjunto de cadenas) Todos los rangos IPv4 e IPv6 que estarán disponibles para los peers BGP. Las direcciones IPv4 deben ser /8 o menores con un tamaño mínimo de /29. Las IPv6 deben ser /56 o menores con un tamaño mínimo de /64. Los rangos no deben solaparse con otros rangos dentro del VRF.
• local_asn (Número) El ASN de 4 bytes establecido en el VRF.

Sólo lectura

• id (Cadena) El ID de este recurso.

Importar

Este recurso puede importarse utilizando un ID VRF existente:

terraform import equinix_metal_vrf {existing_id}