~> Deprecation Notice Equinix Metal llegará al final de su vida útil en 30 de junio de 2026. Todos los recursos Metal se eliminarán en la versión 5.0.0 de este proveedor. Utilice la versión 4.x de este proveedor para seguir utilizándolo hasta el final de su vida útil. Consulte https://docs.equinix.com/metal/ para obtener más información.

equinix_metal_port_vlan_attachment (Recurso)

Proporciona un recurso para adjuntar puertos de dispositivos a VLAN.

El dispositivo y la VLAN deben estar en el mismo metro.

Si necesita este recurso para volver a añadir el puerto a enlace al eliminarlo, establezca force_bond = true.

Para obtener más información sobre las redes de capa 2 en Equinix Metal, consulte

• https://docs.equinix.com/metal/layer2-networking/overview/

Ejemplo de uso

Tipo de red híbrida

resource "equinix_metal_vlan" "test" {
  description = "VLAN in New York"
  metro       = "ny"
  project_id  = local.project_id
}

resource "equinix_metal_device" "test" {
  hostname         = "test"
  plan             = "c3.small.x86"
  metro            = "ny"
  operating_system = "ubuntu_24_04"
  billing_cycle    = "hourly"
  project_id       = local.project_id
}

resource "equinix_metal_device_network_type" "test" {
  device_id = equinix_metal_device.test.id
  type      = "hybrid"
}

resource "equinix_metal_port_vlan_attachment" "test" {
  device_id = equinix_metal_device_network_type.test.id
  port_name = "eth1"
  vlan_vnid = equinix_metal_vlan.test.vxlan
}

Red de capa 2

resource "equinix_metal_device" "test" {
  hostname         = "test"
  plan             = "c3.small.x86"
  metro            = "ny"
  operating_system = "ubuntu_24_04"
  billing_cycle    = "hourly"
  project_id       = local.project_id
}

resource "equinix_metal_device_network_type" "test" {
  device_id = equinix_metal_device.test.id
  type      = "layer2-individual"
}

resource "equinix_metal_vlan" "test1" {
  description = "VLAN in New York"
  metro       = "ny"
  project_id  = local.project_id
}

resource "equinix_metal_vlan" "test2" {
  description = "VLAN in New Jersey"
  metro       = "ny"
  project_id  = local.project_id
}

resource "equinix_metal_port_vlan_attachment" "test1" {
  device_id = equinix_metal_device_network_type.test.id
  vlan_vnid = equinix_metal_vlan.test1.vxlan
  port_name = "eth1"
}

resource "equinix_metal_port_vlan_attachment" "test2" {
  device_id  = equinix_metal_device_network_type.test.id
  vlan_vnid  = equinix_metal_vlan.test2.vxlan
  port_name  = "eth1"
  native     = true
  depends_on = ["equinix_metal_port_vlan_attachment.test1"]
}

Argumento de referencia

Se admiten los siguientes argumentos:

• device_id - (Obligatorio) ID del dispositivo que se va a asignar a la VLAN.
• port_name - (Obligatorio) Nombre del puerto de red que se asignará a la VLAN.
• vlan_vnid - (Obligatorio) Identificador de red VXLAN.
• force_bond - (Opcional) Añade el puerto de nuevo al enlace cuando se elimina este recurso. Por defecto es false.
• native - (Opcional) Marcar esta VLAN como VLAN nativa en el puerto. Sólo puede utilizarse si esta asignación asigna una segunda o más VLAN al puerto. Para asegurarse de que esta asignación no es la primera en un puerto, puede utilizar depends_on apuntando a otra equinix_metal_port_vlan_attachment, igual que en el ejemplo de capa 2-individual anterior.

Atributo Referencia

Además de todos los argumentos anteriores, se exportan los siguientes atributos:

• id - UUID del puerto del dispositivo utilizado en la asignación.
• vlan_id - UUID del recurso API VLAN.
• port_id - UUID del puerto del dispositivo.