Ir al contenido principal

~> Deprecation Notice Equinix Metal llegará al final de su vida útil en 30 de junio de 2026. Todos los recursos Metal se eliminarán en la versión 5.0.0 de este proveedor. Utilice la versión 4.x de este proveedor para seguir utilizándolo hasta el final de su vida útil. Consulte https://docs.equinix.com/metal/ para obtener más información.

equinix_metal_connection (Recurso)

Utilice este recurso para solicitar la creación de un activo de Interconexión para conectarse con otras partes utilizando [Equinix Fabric - interconexiones definidas por software.

Ejemplo de uso​

Conexión virtual compartida facturada por Fabric - Conexión no redundante desde su propio puerto Equinix Fabric a Equinix Metal​

resource "equinix_metal_vlan" "example" {
  project_id = "<metal_project_id>"
  metro      = "FR"
}

resource "equinix_metal_connection" "example" {
  name               = "tf-metal-from-port"
  project_id         = "<metal_project_id>"
  type               = "shared"
  redundancy         = "primary"
  metro              = "FR"
  speed              = "200Mbps"
  service_token_type = "z_side"
  contact_email      = "username@example.com"
  vlans              = [equinix_metal_vlan.example.vxlan]
}

data "equinix_fabric_ports" "a_side" {
  filters {
    name = "<name_of_port||port_prefix>"
  }
}

resource "equinix_fabric_connection" "example" {
  name      = "tf-metal-from-port"
  type      = "EVPL_VC"
  bandwidth = "200"
  notifications {
    type   = "ALL"
    emails = ["username@example.com"]
  }
  order { purchase_order_number = "1-323292" }
  project { project_id = "<fabric_project_id>" }
  a_side {
    access_point {
      type = "COLO"
      port {
        uuid = data.equinix_fabric_ports.a_side.data.0.uuid
      }
      link_protocol {
        type     = "DOT1Q"
        vlan_tag = 1234
      }
    }
  }
  z_side {
    service_token {
      uuid = equinix_metal_connection.example.service_tokens.0.id
    }
  }
}

-> NOTA: Existe un [módulo Equinix Fabric L2 Connection To Equinix Metal Terraform disponible con ejemplos completos de conexiones desde Fabric Ports, Network Edge Devices o Service Tokens. Eche un vistazo al [ejemplo de conexión compartida con Z-side Service Token.

Conexión virtual compartida facturada por Fabric - Conexión no redundante desde su propio dispositivo Network Edge a Equinix Metal​

resource "equinix_metal_vrf" "example" {
  name       = "tf-metal-from-ne"
  metro      = "FR"
  local_asn  = "65001"
  ip_ranges  = ["10.99.1.0/24"]
  project_id = equinix_metal_project.test.id
}

resource "equinix_metal_connection" "example" {
  name               = "tf-metal-from-ne"
  project_id         = "<metal_project_id>"
  type               = "shared"
  redundancy         = "primary"
  metro              = "FR"
  speed              = "200Mbps"
  service_token_type = "z_side"
  contact_email      = "username@example.com"
  vrfs               = [equinix_metal_vrf.example.vxlan]
}

resource "equinix_fabric_connection" "example" {
  name      = "tf-metal-from-ne"
  type      = "EVPL_VC"
  bandwidth = "200"
  notifications {
    type   = "ALL"
    emails = ["username@example.com"]
  }
  order { purchase_order_number = "1-323292" }
  project { project_id = "<fabric_project_id>" }
  a_side {
    access_point {
      type = "VD"
      virtual_device {
        type = "EDGE"
        uuid = equinix_network_device.example.id
      }
    }
  }
  z_side {
    service_token {
      uuid = equinix_metal_connection.example.service_tokens.0.id
    }
  }
}

Conexión virtual compartida facturada por Fabric- Conexión no redundante desde el Fabric Cloud Router de Equinix a Equinix Metal​

resource "equinix_metal_vlan" "example1" {
  project_id = "<metal_project_id>"
  metro      = "SV"
}

resource "equinix_metal_connection" "example" {
  name          = "tf-metal-from-fcr"
  project_id    = "<metal_project_id>"
  metro         = "SV"
  redundancy    = "primary"
  type          = "shared_port_vlan"
  contact_email = "username@example.com"
  speed         = "200Mbps"
  vlans         = [equinix_metal_vlan.example1.vxlan]
}

resource "equinix_fabric_connection" "example" {
  name      = "tf-metal-from-fcr"
  type      = "IP_VC"
  bandwidth = "200"
  notifications {
    type   = "ALL"
    emails = ["username@example.com"]
  }
  project { project_id = "<fabric_project_id>" }
  a_side {
    access_point {
      type = "CLOUD_ROUTER"
      router {
        uuid = equinix_fabric_cloud_router.example.id
      }
    }
  }
  z_side {
    access_point {
      type               = "METAL_NETWORK"
      authentication_key = equinix_metal_connection.example.authorization_code
    }
  }
}

Conexión virtual compartida facturada por Metal - Conexión redundante desde Equinix Metal a un proveedor de servicios en la nube​

resource "equinix_metal_connection" "example" {
  name               = "tf-metal-2-azure"
  project_id         = "<metal_project_id>"
  type               = "shared"
  redundancy         = "redundant"
  metro              = "SV"
  speed              = "1Gbps"
  service_token_type = "a_side"
  contact_email      = "username@example.com"
}

data "equinix_fabric_service_profiles" "zside" {
  filter {
    property = "/name"
    operator = "="
    values   = ["Azure ExpressRoute"]
  }
}

resource "equinix_fabric_connection" "example_primary" {
  name      = "tf-metal-2-azure-pri"
  type      = "EVPL_VC"
  bandwidth = azurerm_express_route_circuit.example.bandwidth_in_mbps
  redundancy { priority = "PRIMARY" }
  notifications {
    type   = "ALL"
    emails = ["username@example.com"]
  }
  project { project_id = "<fabric_project_id>" }
  a_side {
    service_token {
      uuid = equinix_metal_connection.example.service_tokens.0.id
    }
  }
  z_side {
    access_point {
      type               = "SP"
      authentication_key = azurerm_express_route_circuit.example.service_key
      profile {
        type = "L2_PROFILE"
        uuid = data.equinix_fabric_service_profiles.zside.id
      }
      location {
        metro_code = "SV"
      }
    }
  }
}

resource "equinix_fabric_connection" "example_secondary" {
  name      = "tf-metal-2-azure-sec"
  type      = "EVPL_VC"
  bandwidth = azurerm_express_route_circuit.example.bandwidth_in_mbps
  redundancy {
    priority = "SECONDARY"
    group    = one(equinix_fabric_connection.example_primary.redundancy).group
  }
  notifications {
    type   = "ALL"
    emails = ["username@example.com"]
  }
  project { project_id = "<fabric_project_id>" }
  a_side {
    service_token {
      uuid = equinix_metal_connection.example.service_tokens.1.id
    }
  }
  z_side {
    access_point {
      type               = "SP"
      authentication_key = azurerm_express_route_circuit.example.service_key
      profile {
        type = "L2_PROFILE"
        uuid = data.equinix_fabric_service_profiles.zside.id
      }
      location {
        metro_code = "SV"
      }
    }
  }
}

-> NOTA: Existen varios [módulos Terraform de conexión L2 de Equinix Fabric disponibles con ejemplos completos de conexiones desde puertos Fabric, dispositivos Network Edge o Service Token a los proveedores de servicios en nube más populares. Eche un vistazo a los ejemplos de conexión compartida Equinix Metal con Token de Servicio del lado A incluido en cada uno de ellos: AWS, Azure, [Google Cloud, [IBM Cloud, [Oracle Cloud, [Alibaba Cloud.

Conexión virtual compartida facturada por Metal - Conexión no redundante desde Equinix Metal a su propio puerto Equinix Fabric​

resource "equinix_metal_connection" "example" {
  name               = "tf-metal-2-port"
  project_id         = "<metal_project_id>"
  type               = "shared"
  redundancy         = "redundant"
  metro              = "FR"
  speed              = "1Gbps"
  service_token_type = "a_side"
  contact_email      = "username@example.com"
}

data "equinix_fabric_ports" "a_side" {
  filters {
    name = "<name_of_port||port_prefix>"
  }
}

resource "equinix_fabric_connection" "example" {
  name = "tf-metal-2-port"
  type = "EVPL_VC"
  notifications {
    type   = "ALL"
    emails = ["username@example.com"]
  }
  project {
    project_id = "<fabric_project_id>"
  }
  bandwidth = "100"
  order {
    purchase_order_number = "1-323292"
  }
  a_side {
    service_token {
      uuid = equinix_metal_connection.example.service_tokens.0.id
    }
  }
  z_side {
    access_point {
      type = "COLO"
      port {
        uuid = data.equinix_fabric_ports.a_side.data.0.uuid
      }
      link_protocol {
        type     = "DOT1Q"
        vlan_tag = 1234
      }
    }
  }
}

Esquema​

Requerido​

  • name (Cadena) Nombre del recurso de conexión
  • redundancy (Cadena) Redundancia de la conexión - redundante o primaria
  • type (Cadena) Tipo de conexión - dedicada, compartida o shared_port_vlan

Opcional:​

  • contact_email (Cadena) El correo electrónico preferido utilizado para la comunicación y las notificaciones sobre la interconexión Equinix Fabric.
  • description (Cadena) Descripción del recurso de conexión
  • facility (String, Deprecated) Instalación donde se creará la conexión
  • metro (Cadena) Metro donde se creará la conexión
  • mode (Cadena) Modo para conexiones en instalaciones IBX con el tipo dedicado - estándar o túnel
  • organization_id (Cadena) ID de la organización responsable de la conexión. Aplicable con el tipo "dedicado".
  • project_id (Cadena) ID del proyecto al que se refiere la conexión. Obligatorio con el tipo "compartido".
  • service_token_type (Cadena) Sólo se utiliza con conexión compartida. Tipo de token de servicio a utilizar para la conexión, lado_a o lado_z.
  • speed (Cadena) Velocidad de conexión - Los valores deben tener el formato 'Mbps' o 'Gpbs', por ejemplo '100Mbps' o '50Gbps'. Los valores reales admitidos dependerán del tipo de conexión y de si ésta utiliza VLAN o VRF.
  • tags (Lista de cadenas) Etiquetas adjuntas a la conexión
  • vlans (Lista de número) Sólo se utiliza con conexión compartida. VLAN a adjuntar. Pase una vlan para la conexión primaria/única y dos vlans para la conexión redundante.
  • vrfs (Lista de cadenas) Sólo se utiliza con conexión compartida. VRFs a adjuntar. Pase un VRF para la conexión primaria/única y dos VRF para la conexión redundante.

Sólo lectura​

  • authorization_code (Cadena) Sólo se utiliza con la conexión compartida de Fabric. Fabric utiliza este token para poder dar información más detallada sobre el extremo Metal de la red, al ver los recursos desde dentro de Fabric.
  • id (Cadena) El identificador único del recurso
  • ports (Lista de objeto) Lista de puertos de conexión - primario (ports[0]) y secundario (ports[1]) (véase abajo para esquema anidado)
  • service_tokens (Lista de objeto) Sólo se utiliza con conexión compartida. Lista de tokens de servicio necesarios para continuar el proceso de configuración con equinix_fabric_connection o desde el [Equinix Fabric Portal (véase más abajo para el esquema anidado)
  • status (Cadena) Estado del recurso de conexión
  • token (String, Deprecated) Sólo se utiliza con conexión compartida. Fabric Token necesario para continuar el proceso de configuración con equinix_fabric_connection o desde el [Equinix Fabric Portal

Esquema anidado para ports​

Sólo lectura:

  • id (Cadena)
  • link_status (Cadena)
  • name (Cadena)
  • role (Cadena)
  • speed (Número)
  • status (Cadena)
  • virtual_circuit_ids (Lista de cadenas)

Esquema anidado para service_tokens​

Sólo lectura:

  • expires_at (Cadena)
  • id (Cadena)
  • max_allowed_speed (Cadena)
  • role (Cadena)
  • state (Cadena)
  • type (Cadena)
¿Fue útil esta página?